src/virtualization/lib/vsh/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("vsh") {
  testonly = true

  deps = [
    ":client",
    ":tests",
    ":util",
  ]
}

group("tests") {
  testonly = true

  deps = [ ":vsh_tests" ]
}

source_set("util") {
  sources = [
    "util.cc",
    "util.h",
  ]
  deps = [
    "//src/lib/fxl",
    "//third_party/protobuf:protobuf_lite",
    "//zircon/system/ulib/zx",
  ]
}

source_set("client") {
  sources = [
    "client.cc",
    "client.h",
    "command_runner.cc",
    "command_runner.h",
  ]
  deps = [
    ":util",
    "//sdk/fidl/fuchsia.virtualization",
    "//sdk/lib/fit-promise",
    "//src/lib/fxl",
    "//src/virtualization/third_party/vm_tools:vsh_cc_proto",
    "//zircon/system/ulib/zx",
  ]
}

executable("vsh_unittest") {
  visibility = [ "*:*" ]
  testonly = true

  sources = [
    "command_runner_unittest.cc",
    "util_unittest.cc",
  ]

  deps = [
    ":client",
    ":util",
    "//sdk/fidl/fuchsia.virtualization",
    "//sdk/lib/sys/cpp/testing:unit",
    "//sdk/lib/virtualization/testing",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
    "//src/virtualization/third_party/vm_tools:vsh_cc_proto",
  ]
}

fuchsia_unittest_package("vsh_tests") {
  deps = [ ":vsh_unittest" ]
}