src/devices/block/drivers/gpt/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [
    ":gpt-device-test",
    ":gpt_bind_test",
  ]
}

driver_bind_rules("gpt_bind") {
  rules = "gpt.bind"
  header_output = "gpt_bind.h"
  bind_output = "gpt.bindbc"
  tests = "bind_tests.json"
  deps = [
    "//src/devices/bind/fuchsia.compat",
    "//src/devices/bind/fuchsia.hardware.block",
  ]
}

fuchsia_driver("gpt-driver") {
  output_name = "gpt"
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  sources = [ "gpt.cc" ]
  deps = [
    ":gpt_bind",
    "//sdk/banjo/fuchsia.hardware.block:fuchsia.hardware.block_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.block.partition:fuchsia.hardware.block.partition_banjo_cpp",
    "//sdk/lib/fit",
    "//sdk/lib/syslog/cpp:backend_legacy",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
    "//src/storage/gpt",
    "//zircon/system/ulib/sync",
    "//zircon/third_party/ulib/cksum",
  ]
}

fuchsia_driver_component("gpt") {
  component_name = "gpt"
  deps = [ ":gpt-driver" ]
  info = "gpt-info.json"
  colocate = true
}

test("gpt-device-test-bin") {
  output_name = "gpt-device-test"
  sources = [
    "gpt.cc",
    "gpt_device_test.cc",
  ]
  deps = [
    ":gpt_bind",
    "//sdk/banjo/fuchsia.hardware.block:fuchsia.hardware.block_banjo_cpp",
    "//sdk/banjo/fuchsia.hardware.block.partition:fuchsia.hardware.block.partition_banjo_cpp",
    "//sdk/lib/fit",
    "//src/devices/testing/mock-ddk",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//src/storage/gpt",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/zircon-internal",
    "//zircon/system/ulib/zx",
    "//zircon/system/ulib/zxtest",
    "//zircon/third_party/ulib/cksum",
  ]
}

fuchsia_unittest_package("gpt-device-test") {
  deps = [ ":gpt-device-test-bin" ]
}