third_party/pigweed/backends/pw_log/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build_overrides/pigweed.gni")

config("public_include_path") {
  include_dirs = [ "public" ]
}

config("backend_config") {
  include_dirs = [ "public_overrides" ]
}

source_set("pw_log") {
  public = [
    "public/pw_log_fuchsia/log_fuchsia.h",
    "public_overrides/pw_log_backend/log_backend.h",
  ]
  sources = [ "log_fuchsia.cc" ]
  public_configs = [
    ":backend_config",
    ":public_include_path",
  ]
  public_deps = [
    "$dir_pw_log:facade",
    dir_pw_preprocessor,
  ]
  deps = [ "$dir_pw_string:builder" ]
}

# pw_log backends must provide their own "impl" target that collects their
# actual dependencies. The backend "impl" group may be empty if everything can
# go directly in the backend target without causing circular dependencies.
source_set("pw_log.impl") {
}

source_set("syslog") {
  sources = [ "log_syslog.cc" ]
  deps = [
    ":pw_log",
    "//sdk/lib/syslog/cpp",
  ]
}

source_set("printf") {
  sources = [ "log_printf.cc" ]
  deps = [ ":pw_log" ]
}

source_set("dfv1") {
  sources = [ "log_dfv1.cc" ]
  deps = [
    ":pw_log",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
  ]
}

source_set("dfv2") {
  sources = [ "log_dfv2.cc" ]
  deps = [
    ":pw_log",
    "//sdk/lib/driver/logging/cpp",
  ]
}