src/zircon/bin/vsock_service/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_library.gni")

rustc_binary("bin") {
  name = "vsock_service"
  edition = "2021"

  deps = [
    ":lib",
    "//sdk/fidl/fuchsia.hardware.vsock:fuchsia.hardware.vsock_rust",
    "//sdk/lib/device-watcher/rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-fs",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:tracing",
  ]

  sources = [ "src/main.rs" ]
}

rustc_library("lib") {
  name = "vsock_service_lib"
  edition = "2021"
  with_unit_tests = true
  deps = [
    "//sdk/fidl/fuchsia.hardware.vsock:fuchsia.hardware.vsock_rust",
    "//sdk/fidl/fuchsia.vsock:fuchsia.vsock_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-sync",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:crossbeam",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:thiserror",
    "//third_party/rust_crates:tracing",
  ]

  sources = [
    "src/addr.rs",
    "src/lib.rs",
    "src/port.rs",
    "src/service.rs",
  ]
}

fuchsia_package_with_single_component("vsock_service") {
  manifest = "meta/vsock_service.cml"
  deps = [ ":bin" ]
}

fuchsia_unittest_package("vsock_service-tests") {
  deps = [ ":lib_test" ]
}