src/lib/fasync/tests/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/test.gni")
import("//build/testing/environments.gni")

group("tests") {
  testonly = true
  deps = [
    ":fasync-test($host_toolchain)",
    ":fasync-tests",
  ]
}

test("fasync-test") {
  sources = [
    "barrier_tests.cc",
    "bridge_tests.cc",
    "compiler_tests.cc",
    "future_example.cc",
    "future_tests.cc",
    "old_future_tests.cc",
    "pending_task_tests.cc",
    "poll_tests.cc",
    "scheduler_tests.cc",
    "scope_tests.cc",
    "sequencer_tests.cc",
    "single_threaded_executor_tests.cc",
    "suspended_task_tests.cc",
    "test_utils.h",
    "type_traits_tests.cc",
  ]
  deps = [
    "//src/lib/fasync",
    "//zircon/system/ulib/zxtest",
  ]
}

test("fexecutor-test") {
  sources = [ "fexecutor_tests.cc" ]
  deps = [
    "//src/lib/fasync",
    "//src/lib/fasync:fexecutor",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_component("fasync-test-component") {
  component_name = "fasync-test"
  deps = [ ":fasync-test" ]
}

fuchsia_unittest_component("fexecutor-test-component") {
  component_name = "fexecutor-test"
  deps = [ ":fexecutor-test" ]
}

fuchsia_test_package("fasync-tests") {
  test_components = [
    ":fasync-test-component",
    ":fexecutor-test-component",
  ]
  test_specs = {
    environments = [ emu_env ]
  }
}