zircon/system/utest/fit/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

test("fit") {
  sources = [
    "function_tests.cpp",
    "nullable_tests.cpp",
    "optional_tests.cpp",
    "result_tests.cpp",
    "traits_tests.cpp",
  ]
  deps = [
    "$zx/system/ulib/fit",
    "$zx/system/ulib/unittest",
  ]
  configs += [ ":config" ]
  if (is_fuchsia) {
    defines = [ "FIT_NO_STD_FOR_ZIRCON_USERSPACE" ]
    deps += [ "$zx/system/ulib/fdio" ]
  } else {
    sources += [
      "bridge_tests.cpp",
      "defer_tests.cpp",
      "examples/function_example1.cpp",
      "examples/function_example2.cpp",
      "examples/promise_example1.cpp",
      "examples/promise_example2.cpp",
      "examples/utils.cpp",
      "future_tests.cpp",
      "pending_task_tests.cpp",
      "promise_tests.cpp",
      "scheduler_tests.cpp",
      "scope_tests.cpp",
      "sequencer_tests.cpp",
      "single_threaded_executor_tests.cpp",
      "suspended_task_tests.cpp",
      "variant_tests.cpp",
    ]
  }
}

# chromium uses this library, and enables the following flag,
# so these tests should work with this flag enabled
config("config") {
  if (!is_gcc) {
    cflags_cc = [ "-Wshadow" ]
  }
}