src/testing/end_to_end/honeydew/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/fidl/toolchain.gni")
import("//build/python/python_library.gni")
import("//build/testing/host_test_data.gni")

group("honeydew") {
  testonly = true

  deps = [ ":honeydew_no_testonly" ]
}

python_library("honeydew_no_testonly") {
  # In-tree-only tests should prefer ":honeydew" because that enforces that only
  # testonly code uses regular Honeydew. This target should be used for tests or
  # dependencies of tests that are packaged into the SDK, since they cannot be
  # testonly.
  visibility = [
    ":*",
    "//src/testing/end_to_end/mobly_controller:*",

    # SDK-based test targets listed below.
    "//src/tests/end_to_end/rtc:*",
  ]

  enable_mypy = true
  library_name = "honeydew"
  source_root = "//src/testing/end_to_end/honeydew/honeydew"
  sources = [
    "__init__.py",
    "affordances/__init__.py",
    "affordances/ffx/__init__.py",
    "affordances/ffx/session.py",
    "affordances/ffx/ui/__init__.py",
    "affordances/ffx/ui/screenshot.py",
    "affordances/fuchsia_controller/__init__.py",
    "affordances/fuchsia_controller/rtc.py",
    "affordances/fuchsia_controller/tracing.py",
    "affordances/sl4f/__init__.py",
    "affordances/sl4f/bluetooth/__init__.py",
    "affordances/sl4f/bluetooth/bluetooth_common.py",
    "affordances/sl4f/bluetooth/profiles/__init__.py",
    "affordances/sl4f/bluetooth/profiles/bluetooth_avrcp.py",
    "affordances/sl4f/bluetooth/profiles/bluetooth_gap.py",
    "affordances/sl4f/tracing.py",
    "affordances/sl4f/ui/__init__.py",
    "affordances/sl4f/ui/user_input.py",
    "affordances/sl4f/wlan/__init__.py",
    "affordances/sl4f/wlan/wlan.py",
    "affordances/sl4f/wlan/wlan_policy.py",
    "affordances/starnix/__init__.py",
    "affordances/starnix/system_power_state_controller.py",
    "auxiliary_devices/__init__.py",
    "auxiliary_devices/power_switch_dmc.py",
    "errors.py",
    "fuchsia_device/__init__.py",
    "fuchsia_device/base_fuchsia_device.py",
    "fuchsia_device/fuchsia_controller/__init__.py",
    "fuchsia_device/fuchsia_controller/fuchsia_device.py",
    "fuchsia_device/fuchsia_controller_preferred/__init__.py",
    "fuchsia_device/fuchsia_controller_preferred/fuchsia_device.py",
    "fuchsia_device/sl4f/__init__.py",
    "fuchsia_device/sl4f/fuchsia_device.py",
    "interfaces/__init__.py",
    "interfaces/affordances/__init__.py",
    "interfaces/affordances/bluetooth/bluetooth_common.py",
    "interfaces/affordances/bluetooth/profiles/bluetooth_avrcp.py",
    "interfaces/affordances/bluetooth/profiles/bluetooth_gap.py",
    "interfaces/affordances/rtc.py",
    "interfaces/affordances/session.py",
    "interfaces/affordances/system_power_state_controller.py",
    "interfaces/affordances/tracing.py",
    "interfaces/affordances/ui/__init__.py",
    "interfaces/affordances/ui/screenshot.py",
    "interfaces/affordances/ui/user_input.py",
    "interfaces/affordances/wlan/wlan.py",
    "interfaces/affordances/wlan/wlan_policy.py",
    "interfaces/auxiliary_devices/__init__.py",
    "interfaces/auxiliary_devices/power_switch.py",
    "interfaces/device_classes/__init__.py",
    "interfaces/device_classes/affordances_capable.py",
    "interfaces/device_classes/fuchsia_device.py",
    "interfaces/transports/__init__.py",
    "interfaces/transports/fastboot.py",
    "interfaces/transports/ffx.py",
    "interfaces/transports/fuchsia_controller.py",
    "interfaces/transports/sl4f.py",
    "interfaces/transports/ssh.py",
    "transports/__init__.py",
    "transports/fastboot.py",
    "transports/ffx.py",
    "transports/fuchsia_controller.py",
    "transports/sl4f.py",
    "transports/ssh.py",
    "typing/__init__.py",
    "typing/bluetooth.py",
    "typing/custom_types.py",
    "typing/ffx.py",
    "typing/screenshot_image.py",
    "typing/ui.py",
    "typing/wlan.py",
    "utils/__init__.py",
    "utils/common.py",
    "utils/http_utils.py",
    "utils/properties.py",
  ]
  library_deps = [
    ":honeydew_fidl_ir_and_deps",
    "//src/developer/ffx/lib/fuchsia-controller:fidl_bindings",

    # For "ffx starnix adb" command
    "//src/developer/ffx/tools/starnix:ffx_starnix_test_data",
    "//third_party/pypng",
  ]

  # Ensure FIDL-IR dependencies used in Honeydew are supported in SDK.
  assert_no_deps = [
    "//sdk:marker-cts",
    "//sdk:marker-excluded",
    "//sdk:marker-experimental",
    "//sdk:marker-internal",
    "//sdk:marker-unknown",
  ]
}

# This data is specific to ONLY Fuchsia Controller based tests. Other Fuchsia
# Controller based tests will need to add their respective host test data
# definitions to include the proper FIDL IR json.
group("honeydew_fidl_ir_and_deps") {
  # Needed for SDK inclusion.
  testonly = false

  deps = [
    # Required by Fuchsia Controller usage in Honeydew affordances and device claseses.
    "//sdk/fidl/fuchsia.buildinfo:fuchsia.buildinfo_host_test_data",
    "//sdk/fidl/fuchsia.developer.remotecontrol:fuchsia.developer.remotecontrol_host_test_data",
    "//sdk/fidl/fuchsia.diagnostics:fuchsia.diagnostics_host_test_data",
    "//sdk/fidl/fuchsia.feedback:fuchsia.feedback_host_test_data",
    "//sdk/fidl/fuchsia.hardware.power.statecontrol:fuchsia.hardware.power.statecontrol_host_test_data",
    "//sdk/fidl/fuchsia.hardware.rtc:fuchsia.hardware.rtc_host_test_data",
    "//sdk/fidl/fuchsia.hwinfo:fuchsia.hwinfo_host_test_data",
    "//sdk/fidl/fuchsia.io:fuchsia.io_host_test_data",
    "//sdk/fidl/fuchsia.tracing.controller:fuchsia.tracing.controller_host_test_data",

    # Required by Fuchsia Controller itself.
    "//src/developer/ffx/lib/fuchsia-controller/tests:fuchsia_controller_test_data",
  ]
}

# SL4F packages
group("sl4f_packages") {
  testonly = true
  public_deps = [
    "//src/sys/bin/start_sl4f",
    "//src/testing/sl4f",
  ]
}