src/sys/tools/component/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/assembly/bootfs_files_for_assembly.gni")
import("//build/rust/rustc_binary.gni")

rustc_binary("component") {
  visibility = [ ":*" ]
  edition = "2021"

  deps = [
    "//sdk/fidl/fuchsia.dash:fuchsia.dash_rust",
    "//sdk/fidl/fuchsia.sys2:fuchsia.sys2_rust",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-component",
    "//src/lib/fuchsia-url",
    "//src/sys/lib/component_debug",
    "//src/sys/lib/moniker",
    "//src/sys/lib/socket-to-stdio",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:argh",
  ]

  # The component tool is only used in eng products, not production.
  deps += [ "//build/validate:non_production_tag" ]

  # This binary is a part of the bootfs image, so attempt to minimize
  # its size impact.
  configs += [ "//build/config/rust:bootfs" ]

  sources = [
    "src/args.rs",
    "src/main.rs",
  ]
}

bootfs_files_for_assembly("bootfs") {
  deps = [ ":component" ]
}