src/connectivity/wlan/testing/wlantap-driver/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/fuchsia/rules.gni")
import("//build/driver_package.gni")

driver_module("wlantap_driver") {
  output_name = "wlantap"

  sources = [
    "utils.cc",
    "utils.h",
    "wlantap-ctl.cc",
    "wlantap-mac.cc",
    "wlantap-mac.h",
    "wlantap-phy.cc",
    "wlantap-phy.h",
  ]

  deps = [
    "//garnet/lib/wlan/protocol",
    "//sdk/banjo/ddk.hw.wlan.wlaninfo",
    "//sdk/banjo/ddk.protocol.wlanphyimpl",
    "//sdk/fidl/fuchsia.wlan.tap:fuchsia.wlan.tap",
    "//sdk/fidl/fuchsia.wlan.tap:fuchsia.wlan.tap_llcpp",
    "//src/connectivity/wlan/lib/common/cpp:common",
    "//src/devices/lib/driver",
    "//zircon/public/lib/async-cpp",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zx",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",

    # TODO(fxb/38132): Migrate to the new bind rules and delete the below
    "//src/lib/ddk:ddk-deprecated-binding-headers",
  ]

  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [
    "//build/config/fuchsia:enable_zircon_asserts",
    "//build/config/fuchsia:static_cpp_standard_library",
  ]

  # TODO(fxbug.dev/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

driver_package("wlantap") {
  deps = [ ":wlantap_driver" ]

  drivers = [
    {
      name = "wlantap.so"
    },
  ]
}