src/media/audio/drivers/codecs/alc5663/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/config/fuchsia/rules.gni")

bind_rules("alc5663_bind") {
  rules = "alc5663.bind"
  output = "alc5663_bind.h"
  tests = "tests.json"
  deps = [
    "//src/devices/bind/fuchsia.i2c",
    "//src/devices/bind/fuchsia.realtek.platform",
  ]
}

# Also used by test/.
source_set("shared") {
  visibility = [ "./*" ]
  configs += [ "//build/config:all_source" ]
  sources = [ "alc5663.cc" ]
  public_deps = [
    ":alc5663_bind",
    "//sdk/banjo/fuchsia.hardware.i2c",
    "//sdk/lib/fit",
    "//src/devices/i2c/lib/device-protocol-i2c",
    "//src/devices/i2c/lib/device-protocol-i2c-channel",
    "//src/lib/ddktl",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/hwreg",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zx",
  ]
}

driver_module("alc5663") {
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  configs += [ "//build/unification/config:zircon-migrated" ]
  deps = [
    ":shared",
    "//src/devices/lib/driver",
    "//src/lib/ddk",
  ]
}

group("tests") {
  testonly = true
  deps = [
    ":alc5663_bind_test",
    "tests",
  ]
}