zircon/system/ulib/minfs/test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

group("test") {
  testonly = true
  deps = [
    ":minfs-integration",
    ":minfs-unit",
  ]
}

zx_test("minfs-unit") {
  test_group = "fs"
  sources = [
    "unit/bcache-test.cc",
    "unit/format-test.cc",
    "unit/fsck-test.cc",
    "unit/inspector-test.cc",
    "unit/journal-test.cc",
    "unit/loader-test.cc",
    "unit/mkfs-test.cc",
    "unit/parser-test.cc",
    "unit/superblock-test.cc",
    "unit/transaction-test.cc",
    "unit/vnode-test.cc",
  ]
  deps = [
    "$zx/system/fidl/fuchsia-minfs:c",
    "$zx/system/ulib/block-client",
    "$zx/system/ulib/block-client:fake-device",
    "$zx/system/ulib/disk-inspector",
    "$zx/system/ulib/fs-management",
    "$zx/system/ulib/fs/test_support",
    "$zx/system/ulib/fvm",
    "$zx/system/ulib/minfs",
    "$zx/system/ulib/storage/buffer/test_support",
    "$zx/system/ulib/sync",
    "$zx/system/ulib/zircon-internal",
    "$zx/system/ulib/zxtest",
    "$zx/third_party/ulib/cksum",
    "$zx/third_party/ulib/safemath",
  ]
  include_dirs = [ "$zx/system/ulib/minfs" ]
  configs += [ "$zx/public/gn/config:static-libc++" ]
}

zx_test("minfs-integration") {
  test_group = "fs"
  sources = [
    "integration/backup-superblock.cc",
    "integration/integration_main.cc",
    "integration/minfs_fixtures.cc",
    "integration/mount_test.cc",
    "integration/truncate_test.cc",
    "integration/utils.cc",
  ]
  deps = [
    "$zx/system/fidl/fuchsia-io:llcpp",
    "$zx/system/ulib/async",
    "$zx/system/ulib/async:async-cpp",
    "$zx/system/ulib/async:async-default",
    "$zx/system/ulib/async-loop",
    "$zx/system/ulib/async-loop:async-loop-cpp",
    "$zx/system/ulib/async-loop:async-loop-default.static",
    "$zx/system/ulib/fdio",
    "$zx/system/ulib/fs-management",
    "$zx/system/ulib/fs-test-utils",
    "$zx/system/ulib/fs/test/posix:posix_tests",
    "$zx/system/ulib/fs/test_support",
    "$zx/system/ulib/memfs",
    "$zx/system/ulib/minfs",
    "$zx/system/ulib/zircon",
    "$zx/system/ulib/zx",
    "$zx/system/ulib/zxtest",
  ]
}

zx_test("minfs-host") {
  sources = [ "host/bcache-test.cc" ]
  deps = [
    "$zx/system/ulib/minfs",
    "$zx/system/ulib/zxtest",
  ]
}