src/ledger/bin/BUILD.gn

# Copyright 2016 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/fuzzing/fuzzer.gni")
import("//build/package.gni")
import("//build/test.gni")

visibility = [
  "//src/ledger/*",
  "//src/modular/*",
]

package("bin") {
  package_name = "ledger"

  deps = [ "app" ]

  binary = "ledger"

  meta = [
    {
      path = rebase_path("meta/ledger.cmx")
      dest = "ledger.cmx"
    },
  ]
}

test("ledger_unittests") {
  deps = [
    "//src/ledger/bin/app:unittests",
    "//src/ledger/bin/cache:unittests",
    "//src/ledger/bin/clocks/impl:unittests",
    "//src/ledger/bin/cloud_sync/impl:unittests",
    "//src/ledger/bin/encryption/fake:unittests",
    "//src/ledger/bin/encryption/impl:unittests",
    "//src/ledger/bin/encryption/primitives:unittests",
    "//src/ledger/bin/environment:unittests",
    "//src/ledger/bin/fidl/syncable:unittests",
    "//src/ledger/bin/filesystem:unittests",
    "//src/ledger/bin/inspect:unittests",
    "//src/ledger/bin/p2p_sync/impl:unittests",
    "//src/ledger/bin/platform:implementation_unittests",
    "//src/ledger/bin/platform:unittests",
    "//src/ledger/bin/public:unittests",
    "//src/ledger/bin/storage/fake:unittests",
    "//src/ledger/bin/storage/impl:unittests",
    "//src/ledger/bin/storage/impl/btree:unittests",
    "//src/ledger/bin/storage/public:unittests",
    "//src/ledger/bin/storage/testing:unittests",
    "//src/ledger/bin/sync_coordinator/impl:unittests",
    "//src/ledger/bin/sync_helper:unittests",
    "//src/ledger/bin/synchronization:unittests",
    "//src/ledger/bin/testing:gtest_main",
    "//src/ledger/bin/testing:unittests",
  ]

  configs += [ "//src/ledger:ledger_config" ]

  # TODO(46749): Fix the leaks and remove this.
  deps += [ "//build/config/sanitizers:suppress-lsan.DO-NOT-USE-THIS" ]
}

test("ledger_host_tests") {
  deps = [
    "//src/ledger/bin/cache:unittests",
    "//src/ledger/bin/testing:gtest_main",
  ]
}

fuzzers_package("ledger_fuzzers") {
  fuzzers = [
    "//src/ledger/bin/p2p_sync/impl:p2p_sync_fuzzer",
    "//src/ledger/bin/storage/impl/btree:encoding_fuzzer",
    "//src/ledger/bin/storage/impl:leveldb_fuzzer",
    "//src/ledger/bin/storage/impl:clock_serialization_fuzzer",
    "//src/ledger/bin/storage/impl:clock_serialization_device_id_fuzzer",
    "//src/ledger/lib/encoding:encoding_buffer_fuzzer",
  ]
}