src/camera/bin/camera-gym/controller_parser/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

# This group is not currently depended on
group("controller_parser") {
  deps = [ ":lib" ]
}

group("tests") {
  testonly = true
  deps = [ ":camera_gym_controller_parser_unittest" ]
}

source_set("lib") {
  sources = [
    "controller_parser.cc",
    "controller_parser.h",
  ]
  deps = [
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/syslog/cpp",
    "//sdk/lib/syslog/cpp:backend",
    "//src/lib/fxl",
  ]
  public_deps = [
    "//sdk/lib/fit-promise",
    "//src/camera/bin/camera-gym/fidl:controller",
  ]
}

executable("camera_gym_controller_parser_unittest_bin") {
  testonly = true
  sources = [ "controller_parser_unittest.cc" ]
  deps = [
    ":lib",
    "//src/lib/fxl/test:gtest_main",
  ]
}

fuchsia_unittest_package("camera_gym_controller_parser_unittest") {
  deps = [ ":camera_gym_controller_parser_unittest_bin" ]
}