src/virtualization/bin/host_vsock/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("tests") {
  testonly = true

  deps = [ ":host_vsock_tests" ]
}

source_set("lib") {
  sources = [
    "guest_vsock_endpoint.cc",
    "guest_vsock_endpoint.h",
    "host_vsock_endpoint.cc",
    "host_vsock_endpoint.h",
  ]

  public_deps = [
    "//sdk/fidl/fuchsia.sys",
    "//sdk/fidl/fuchsia.virtualization",
    "//sdk/lib/sys/cpp",
    "//src/lib/fxl",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/bitmap",
  ]
}

executable("bin") {
  output_name = "host_vsock"

  sources = [ "main.cc" ]

  deps = [ ":lib" ]
}

fuchsia_package_with_single_component("host_vsock") {
  manifest = "meta/host_vsock.cml"
  deps = [ ":bin" ]
}

executable("host_vsock_unittests") {
  visibility = [ ":*" ]
  testonly = true

  sources = [ "host_vsock_endpoint_unittest.cc" ]

  deps = [
    ":lib",
    "//src/lib/fsl",
    "//src/lib/fxl/test:gtest_main",
    "//src/lib/testing/loop_fixture",
  ]
}

fuchsia_unittest_package("host_vsock_tests") {
  deps = [ ":host_vsock_unittests" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}