garnet/examples/components/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/testing/environments.gni")

group("components") {
  testonly = true

  deps = [
    ":component_hello_world",
    ":component_hello_world_tests",
  ]
}

executable("bin") {
  output_name = "application"

  sources = [ "hello_world.cc" ]

  deps = [ "//zircon/public/lib/zx" ]
}

executable("bin2") {
  output_name = "application2"

  sources = [ "hello_world2.cc" ]

  deps = [ "//zircon/public/lib/zx" ]
}

fuchsia_component("hello_world") {
  manifest = "meta/hello_world.cmx"
  deps = [ ":bin" ]
}

fuchsia_component("hello_world2") {
  manifest = "meta/hello_world2.cmx"
  deps = [ ":bin2" ]
}

fuchsia_package("component_hello_world") {
  deps = [
    ":hello_world",
    ":hello_world2",
  ]
}

executable("hello_world_test") {
  testonly = true
  sources = [ "hello_world_test.cc" ]
  deps = [ "//src/lib/fxl/test:gtest_main" ]
}

fuchsia_unittest_package("component_hello_world_tests") {
  deps = [ ":hello_world_test" ]
  test_specs = {
    environments = [ emu_env ]
  }
}