sdk/lib/driver/mmio/cpp/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/cpp/sdk_source_set.gni")
import("//build/test.gni")

group("tests") {
  testonly = true
  deps = [ ":mmio-unittest-package" ]
}

config("headers.config") {
  include_dirs = [ "." ]
}

sdk_source_set("cpp") {
  category = "partner"
  sdk_name = "driver_mmio_cpp"
  stable = true
  include_base = "//sdk"

  public = [
    "mmio-buffer.h",
    "mmio-internal.h",
    "mmio-ops.h",
    "mmio-pinned-buffer.h",
    "mmio-view.h",
    "mmio.h",
  ]
  sdk_headers_for_internal_use = [ "mmio-internal.h" ]
  public_configs = [ "//sdk/config" ]
  public_deps = [
    # <lib/mmio/mmio.h> has #include <lib/mmio-ptr/mmio-ptr.h>.
    "//zircon/system/ulib/mmio-ptr",

    # <lib/driver/mmio/cpp/mmio-buffer.h> has #include <lib/zx/result.h>.
    "//zircon/system/ulib/zx",
  ]
  sources = [ "mmio-buffer.cc" ]
}

test("mmio-unittest") {
  sources = [ "mmio-buffer-test.cc" ]
  deps = [
    ":cpp",
    "//sdk/lib/driver/mmio/testing/cpp",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("mmio-unittest-package") {
  package_name = "mmio-unittest"
  deps = [ ":mmio-unittest" ]
}