sdk/lib/driver/devicetree/visitors/BUILD.gn

# Copyright 2023 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/cpp/sdk_source_set.gni")

group("tests") {
  deps = [
    "default:tests",
    "drivers:tests",
  ]
  testonly = true
}

sdk_source_set("registry") {
  sdk_name = "devicetree-registry"
  category = "internal"
  include_base = "//sdk"

  public = [ "registry.h" ]
  public_deps = [ "//sdk/lib/driver/devicetree/manager:headers" ]
}

sdk_source_set("load-visitors") {
  sdk_name = "devicetree-load-visitors"
  category = "internal"
  sources = [ "load-visitors.cc" ]

  public = [ "load-visitors.h" ]
  include_base = "//sdk"

  deps = [
    ":registration",
    "default",
    "//sdk/lib/driver/component/cpp",
    "//sdk/lib/driver/logging/cpp",
  ]

  public_deps = [
    ":registry",
    "//sdk/fidl/fuchsia.driver.framework:fuchsia.driver.framework_cpp",
  ]
}

sdk_source_set("driver-visitor") {
  sdk_name = "devicetree-driver-visitors"
  category = "internal"
  sources = [ "driver-visitor.cc" ]
  public = [ "driver-visitor.h" ]
  include_base = "//sdk"
  deps = [ "//sdk/lib/driver/logging/cpp" ]

  public_deps = [
    ":property-parser",
    "//sdk/lib/driver/devicetree/manager:headers",
    "//zircon/system/ulib/zx",
  ]
}

sdk_source_set("multivisitor") {
  sdk_name = "devicetree-multivisitor"
  category = "internal"
  include_base = "//sdk"
  public = [ "multivisitor.h" ]
  public_deps = [ "//sdk/lib/driver/devicetree/manager:headers" ]
}

sdk_source_set("registration") {
  sdk_name = "devicetree-registration"
  category = "internal"
  public = [ "registration.h" ]
  include_base = "//sdk"
  public_deps = [
    "//sdk/lib/driver/devicetree/manager:headers",
    "//sdk/lib/driver/logging/cpp",
  ]
}

sdk_source_set("property-parser") {
  sdk_name = "devicetree-property-parser"
  category = "internal"
  include_base = "//sdk"
  sources = [ "property-parser.cc" ]
  public = [ "property-parser.h" ]
  deps = [
    ":common-types",
    "//sdk/lib/driver/logging/cpp",
  ]
  public_deps = [
    "//sdk/lib/driver/devicetree/manager",
    "//zircon/system/ulib/zx",
  ]
}

source_set("interrupt-parser") {
  sources = [ "interrupt-parser.cc" ]
  public = [ "interrupt-parser.h" ]
  deps = [ "//sdk/lib/driver/logging/cpp" ]
  public_deps = [ ":property-parser" ]
}

sdk_source_set("common-types") {
  sdk_name = "devicetree-common-types"
  category = "internal"
  include_base = "//sdk"

  public = [ "common-types.h" ]
  public_deps = [ "//zircon/kernel/lib/devicetree" ]
}