garnet/public/rust/fuchsia-framebuffer/BUILD.gn

# Copyright 2017 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//build/rust/rustc_binary.gni")
import("//build/rust/rustc_library.gni")
import("//build/test/test_package.gni")

rustc_library("fuchsia-framebuffer") {
  name = "fuchsia_framebuffer"
  version = "0.1.0"
  edition = "2018"
  deps = [
    "//garnet/public/lib/fidl/rust/fidl",
    "//garnet/public/rust/fdio",
    "//garnet/public/rust/fuchsia-async",
    "//garnet/public/rust/fuchsia-component",
    "//garnet/public/rust/fuchsia-runtime",
    "//garnet/public/rust/fuchsia-zircon",
    "//src/lib/mapped-vmo",
    "//src/lib/shared-buffer",
    "//third_party/rust_crates:failure",
    "//third_party/rust_crates:futures",
    "//zircon/system/fidl/fuchsia-hardware-display:fuchsia-hardware-display-rustc",
    "//zircon/system/fidl/fuchsia-sysmem:fuchsia-sysmem-rustc",
  ]
}

rustc_binary("box") {
  version = "0.1.0"
  edition = "2018"
  with_unit_tests = true
  source_root = "examples/box.rs"
  deps = [
    "//garnet/public/rust/fuchsia-async",
    "//garnet/public/rust/fuchsia-framebuffer",
    "//garnet/public/rust/fuchsia-zircon",
    "//third_party/rust_crates:failure",
    "//third_party/rust_crates:futures",
  ]
}

package("fb_box_rs") {
  deps = [
    ":box",
  ]

  binaries = [
    {
      name = "app"
      source = "box"
    },
  ]

  meta = [
    {
      path = rebase_path("meta/box.cmx")
      dest = "fb_box_rs.cmx"
    },
  ]
}

rustc_binary("fb_integration_test_bin") {
  name = "fb_integration_test"
  edition = "2018"
  source_root = "tests/fb_integration_test.rs"
  deps = [
    "//garnet/public/rust/fuchsia-async",
    "//garnet/public/rust/fuchsia-framebuffer",
    "//garnet/public/rust/fuchsia-zircon",
    "//third_party/rust_crates:failure",
    "//third_party/rust_crates:futures",
  ]
}

test_package("fb_integration_test") {
  deps = [
    ":fb_integration_test_bin",
  ]

  tests = [
    {
      name = "fb_integration_test"
      environments = [ nuc_env ]
    },
  ]
}