src/proc/tests/chromiumos/syscalls/BUILD.gn

# Copyright 2022 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/test.gni")
import("//src/proc/tests/chromiumos/build/starnix_linux_test_component.gni")

group("tests") {
  testonly = true
  deps = []

  if (target_cpu == "x64" && !is_asan) {
    deps += [ ":test_chromiumos_syscalls" ]
  }
}

test("syscalls_test_bin") {
  sources = [
    "restart_read_test.cc",
    "trivial_test.cc",
  ]
  deps = [
    "//src/lib/fxl/test:gtest_main",
    "//third_party/googletest:gtest",
  ]
}

starnix_linux_test_component("syscalls_test") {
  test_label = ":syscalls_test_bin"
  test_binary = "syscalls_test_bin"
}

fuchsia_test_package("test_chromiumos_syscalls") {
  test_components = [ ":syscalls_test" ]

  # This package intentionally contains many non-Fuchia ELF binaries that
  # are not under /data/, and some of them are even unstripped, so disable
  # theses checks to build successfully.
  disable_elf_binaries_checks = true
}