system/ulib/fdio/BUILD.gn

# Copyright 2019 The Fuchsia Authors
#
# Use of this source code is governed by a MIT-style
# license that can be found in the LICENSE file or at
# https://opensource.org/licenses/MIT

library("fdio") {
  sdk = "shared"
  sdk_headers = [
    "lib/fdio/debug.h",
    "lib/fdio/io.h",
    "lib/fdio/limits.h",
    "lib/fdio/namespace.h",
    "lib/fdio/private.h",
    "lib/fdio/spawn.h",
    "lib/fdio/unsafe.h",
    "lib/fdio/util.h",
    "lib/fdio/vfs.h",
    "lib/fdio/watcher.h",
  ]
  shared = true
  sources = [
    "bsdsocket.c",
    "debug.c",
    "get-vmo.c",
    "namespace.c",
    "null.c",
    "remoteio.c",
    "socket.c",
    "spawn.c",
    "stubs.c",
    "uname.c",
    "unistd.c",
    "waitable.cpp",
    "watcher.c",
    "zxio.c",
  ]
  configs += [ "$zx/public/gn/config:visibility_hidden" ]
  deps = [
    "$zx/system/fidl/fuchsia-io:c",
    "$zx/system/fidl/fuchsia-ldsvc:c",
    "$zx/system/fidl/fuchsia-net:c",
    "$zx/system/fidl/fuchsia-process:c",
    "$zx/system/ulib/fidl",
    "$zx/system/ulib/zircon",
    "$zx/system/ulib/zx",
    "$zx/system/ulib/zxio",
    "$zx/system/ulib/zxs",
  ]

  # TODO(mcgrathr): Temporary kludge for legacy Fuchsia GN build integration.
  if (toolchain.variant == "gcc" || toolchain.variant == "clang") {
    metadata = {
      images = [
        {
          name = "fdio"
          type = "so"
          path = rebase_path("$target_out_dir/libfdio.so.debug", root_build_dir)
        },
      ]
    }
  }
}