public/dart/fuchsia_webview_flutter/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/dart/dart_library.gni")
import("//build/testing/environments.gni")
import("//topaz/runtime/dart/dart_fuchsia_test.gni")
import("//topaz/runtime/dart/flutter_test.gni")

dart_library("fuchsia_webview_flutter") {
  package_name = "fuchsia_webview_flutter"

  sdk_category = "partner"

  sources = [
    "src/fuchsia_web_services.dart",
    "src/fuchsia_webview.dart",
    "src/fuchsia_webview_platform_controller.dart",
    "src/utils.dart",
    "webview.dart",
  ]

  deps = [
    "//sdk/fidl/fuchsia.net.http",
    "//sdk/fidl/fuchsia.web",
    "//third_party/dart-pkg/git/flutter/packages/flutter",
    "//third_party/dart-pkg/pub/webview_flutter",
    "//topaz/public/dart/fidl",
    "//topaz/public/dart/fuchsia_logger",
    "//topaz/public/dart/fuchsia_scenic",
    "//topaz/public/dart/fuchsia_scenic_flutter",
    "//topaz/public/dart/fuchsia_services",
    "//topaz/public/dart/fuchsia_vfs",
    "//topaz/public/dart/zircon",
    "//zircon/system/fidl/fuchsia-io",
    "//zircon/system/fidl/fuchsia-mem",
  ]
}

# fx run-host-tests fuchsia_webview_flutter_unittests
flutter_test("fuchsia_webview_flutter_unittests") {
  sources = [
    "fuchsia_webview_test.dart",
  ]

  deps = [
    ":fuchsia_webview_flutter",
    "//third_party/dart-pkg/pub/mockito",
    "//third_party/dart-pkg/pub/test",
    "//third_party/dart-pkg/git/flutter/packages/flutter_test",
    "//topaz/public/dart/fuchsia_webview_flutter",
    "//topaz/public/lib/testing/flutter",
  ]
}

# fx run-test fuchsia_services_package_integration_tests
dart_fuchsia_test("fuchsia_webview_flutter_target_tests") {
  meta = [
    {
      path = rebase_path("meta/fuchsia_webview_flutter_target_tests.cmx")
      dest = "fuchsia_webview_flutter_target_tests.cmx"
    },
  ]

  source_dir = "fuchsia_test"

  sources = [
    "fuchsia_webview_target_tests.dart",
  ]

  deps = [
    ":fuchsia_webview_flutter",
    "//third_party/dart-pkg/git/flutter/packages/flutter_test",
    "//third_party/dart-pkg/pub/test",
  ]

  environments = basic_envs
}