fuchsia/upstream-split-cts/BUILD.gn

# Copyright 2021 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components/fuchsia_test_component.gni")
import("//build/components/fuchsia_test_package.gni")
import("//build/packages/exported_fuchsia_package_archive.gni")
import("//src/lib/vulkan/vulkan.gni")

# Add a label of "vulkan-cts" for each environment given in the list
# of general hardware environments for magma tests. The label ensures
# that the Vulkan CTS will not be run in the general test pipeline;
# the label will be keyed on so that the suite may be run in a special
# builder.
labeled_magma_hardware_envs = []
foreach(env, vulkan_envs) {
  labeled_env = {
  }  # Clear from previous iteration.
  labeled_env = {
    forward_variables_from(env, "*")
    if (defined(tags)) {
      tags += [ "vulkan-cts" ]
    } else {
      tags = [ "vulkan-cts" ]
    }
  }
  labeled_magma_hardware_envs += [ labeled_env ]
}

# This matches FRACTION_COUNT in ../gen.py.
cts_item_list = [
  "0",
  "1",
  "2",
  "3",
  "4",
  "5",
  "6",
  "7",
]

cts_components = []
foreach(cts_item, cts_item_list) {
  fuchsia_test_component("vulkan-cts-upstream-split-$cts_item") {
    testonly = true
    manifest = "meta/vulkan-cts-upstream-split-$cts_item.cml"
    deps = [ "..:cts-deps" ]
    test_type = "system"
  }
  cts_components += [ ":vulkan-cts-upstream-split-$cts_item" ]
}

fuchsia_test_package("vulkan-cts-upstream-split") {
  test_components = cts_components
  test_specs = {
    environments = labeled_magma_hardware_envs
  }
}

# Align package naming to simplify OOT consumption.
fuchsia_test_package("vulkan-cts-split") {
  test_components = cts_components
  test_specs = {
    environments = labeled_magma_hardware_envs
  }
}

exported_fuchsia_package_archive("vulkan-cts-split-archive") {
  package = ":vulkan-cts-split"
  testonly = true
  no_output_dir_leaks = false
}