fuchsia/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("resources.gni")

action("build") {
  script = "build.sh"
  args = [ rebase_path(root_out_dir) ]
  deps = [
    "//garnet/public/sdk:zircon_sysroot_export",
    "//third_party/vulkan_loader_and_validation_layers:vulkan",
    "//zircon/public/lib/fdio:fdio_sdk",
  ]

  depfile = "$root_out_dir/build-vulkancts/vulkan-cts.d"
  outputs = [
    "$root_out_dir/build-vulkancts/external/vulkancts/modules/vulkan/deqp-vk",
    "$root_out_dir/build-vulkancts/executor/executor",
    "$root_out_dir/build-vulkancts/execserver/execserver",
    "$root_out_dir/build-vulkancts/cases/dEQP-VK-cases.xml",
  ]
}

copy("copy") {
  sources = [
    "$root_out_dir/build-vulkancts/external/vulkancts/modules/vulkan/deqp-vk",
  ]
  outputs = [
    "$root_build_dir/deqp-vk",
  ]
  deps = [
    ":build",
  ]
}

# To run on device:
# run vulkan-cts --deqp-caselist-file=/pkg/data/vk-default.txt --deqp-log-images=disable --deqp-log-shader-sources=disable --deqp-log-filename=/data/TestResults.qpa
package("vulkan-cts") {
  deps = [
    ":copy",
  ]
  binary = "deqp-vk"
  meta = [
    {
      path = rebase_path("meta/vulkan-cts.cmx")
      dest = "vulkan-cts.cmx"
    },
  ]
  resources = cts_resources
}

# To run on device:
# run vulkan-cts-executor --start-server=/pkg/bin/execserver --testset=dEQP-VK.* --caselistdir=/pkg/data/cases --out=/data/TestLog.qpa --info=/data/infolog.txt --binaryname=/pkg/bin/deqp-vk --workdir=/data
# Note: the list of cases may include tests that aren't in vk-default.txt "mustpass".
package("vulkan-cts-executor") {
  deps = [
    ":build",
  ]

  binary = "build-vulkancts/executor/executor"
  binaries = [
    {
      name = "deqp-vk"
      source = "$root_out_dir/build-vulkancts/external/vulkancts/modules/vulkan/deqp-vk"
    },
    {
      name = "execserver"
      source = "$root_out_dir/build-vulkancts/execserver/execserver"
    },
  ]
  meta = [
    {
      path = rebase_path("meta/vulkan-cts-executor.cmx")
      dest = "vulkan-cts-executor.cmx"
    },
  ]
  resources = cts_resources

  resources += [
    {
      path = rebase_path("$root_out_dir/build-vulkancts/cases/dEQP-VK-cases.xml")
      dest = "cases/dEQP-VK-cases.xml"
    },
  ]
}

# On device:
# run vulkan-cts-execserver
# Run on host:
# executor/executor --connect=192.168.42.80 --testset=dEQP-VK.* --caselistdir=cases/ --binaryname=/pkg/bin/deqp-vk --workdir=/data --cmdline="--deqp-log-images=disable --deqp-log-shader-sources=disable"
# Note: the list of cases may include tests that aren't in vk-default.txt "mustpass".
package("vulkan-cts-execserver") {
  deps = [
    ":build",
  ]

  binary = "build-vulkancts/execserver/execserver"
  binaries = [
    {
      name = "deqp-vk"
      source = "$root_out_dir/build-vulkancts/external/vulkancts/modules/vulkan/deqp-vk"
    },
  ]
  meta = [
    {
      path = rebase_path("meta/vulkan-cts-execserver.cmx")
      dest = "vulkan-cts-execserver.cmx"
    },
  ]
  resources = cts_resources

  resources += [
    {
      path = rebase_path("$root_out_dir/build-vulkancts/cases/dEQP-VK-cases.xml")
      dest = "cases/dEQP-VK-cases.xml"
    },
  ]
}