java_src/src/main/java/com/google/crypto/tink/config/BUILD.bazel

load("@build_bazel_rules_android//android:rules.bzl", "android_library")
load("@bazel_skylib//rules:common_settings.bzl", "bool_flag")

licenses(["notice"])

package(default_visibility = ["//visibility:public"])

java_library(
    name = "tink_config",
    srcs = ["TinkConfig.java"],
    deps = [
        "//proto:config_java_proto",
        "//src/main/java/com/google/crypto/tink/daead:deterministic_aead_config",
        "//src/main/java/com/google/crypto/tink/hybrid:hybrid_config",
        "//src/main/java/com/google/crypto/tink/prf:prf_config",
        "//src/main/java/com/google/crypto/tink/signature:signature_config",
        "//src/main/java/com/google/crypto/tink/streamingaead:streaming_aead_config",
    ],
)

android_library(
    name = "tink_config-android",
    srcs = ["TinkConfig.java"],
    deps = [
        "//proto:config_java_proto_lite",
        "//src/main/java/com/google/crypto/tink/daead:deterministic_aead_config-android",
        "//src/main/java/com/google/crypto/tink/hybrid:hybrid_config-android",
        "//src/main/java/com/google/crypto/tink/prf:prf_config-android",
        "//src/main/java/com/google/crypto/tink/signature:signature_config-android",
        "//src/main/java/com/google/crypto/tink/streamingaead:streaming_aead_config-android",
    ],
)

bool_flag(
    name = "use_only_fips",
    build_setting_default = False,
)

config_setting(
    name = "fips_enabled",
    flag_values = {":use_only_fips": "True"},
    visibility = ["//visibility:public"],
)

java_library(
    name = "tink_fips_status",
    srcs = select({
        ":fips_enabled": ["TinkFipsEnabled.java"],
        "//conditions:default": ["TinkFipsDisabled.java"],
    }),
    deps = select({
        ":fips_enabled": [
            "@maven//:org_conscrypt_conscrypt_openjdk_uber",
        ],
        "//conditions:default": [
        ],
    }),
)

android_library(
    name = "tink_fips_status-android",
    srcs = select({
        ":fips_enabled": ["TinkFipsEnabled.java"],
        "//conditions:default": ["TinkFipsDisabled.java"],
    }),
)

java_library(
    name = "tink_fips",
    srcs = ["TinkFips.java"],
    visibility = ["//visibility:public"],
    deps = [
        ":tink_fips_status",
    ],
)

android_library(
    name = "tink_fips-android",
    srcs = ["TinkFips.java"],
    visibility = ["//visibility:public"],
    deps = [
        ":tink_fips_status-android",
        "@maven//:org_conscrypt_conscrypt_openjdk_uber",
    ],
)