BUILD.gn

# Copyright 2017 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("binaries.gni")

group("bins") {
  deps = []

  foreach(bin, sbase_binaries) {
    deps += [ ":${bin}_bin" ]
  }
}

config("sbase_config") {
  cflags = [
    "-Wno-implicit-fallthrough",
    "-Wno-missing-field-initializers",
    "-Wno-sign-compare",
    "-Wno-sometimes-uninitialized",
    "-Wno-strict-prototypes",
    "-Wno-tautological-constant-out-of-range-compare",
    "-Wno-write-strings",
  ]
}

foreach(bin, sbase_binaries) {
  executable("${bin}_bin") {
    output_name = bin

    sources = [ "$bin.c" ]

    deps = [
      "libutf",
      "libutil",
      "//sdk/lib/fdio",
      "//src/zircon/lib/zircon",
    ]

    configs += [ ":sbase_config" ]
  }

  fuchsia_package("${bin}_pkg") {
    package_name = bin
    deps = [ ":${bin}_bin" ]
  }
}

group("sbase-pkgs") {
  deps = []
  foreach(bin, sbase_binaries) {
    deps += [ ":${bin}_pkg" ]
  }
}