src/gbm/BUILD.gn

# Copyright 2016 The Fuchsia Authors
#
# Permission is hereby granted, free of charge, to any person obtaining a
# copy of this software and associated documentation files (the "Software"),
# to deal in the Software without restriction, including without limitation
# the rights to use, copy, modify, merge, publish, distribute, sublicense,
# and/or sell copies of the Software, and to permit persons to whom the
# Software is furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice (including the next
# paragraph) shall be included in all copies or substantial portions of the
# Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
# THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
# IN THE SOFTWARE.

import("//garnet/lib/magma/gnbuild/magma.gni")

shared_library("gbm") {
  public_deps = [
    ":dri_backend",
    ":main",
  ]
}

source_set("gbm_source") {
  public_deps = [
    ":dri_backend",
    ":main",
  ]
}

config("gbm_main_config") {
  include_dirs = [ "$mesa_build_root/src/gbm/main" ]
}

source_set("main") {
  cflags = [ "-fPIC" ]

  public_configs = [ ":gbm_main_config" ]

  sources = [
    "main/backend.c",
    "main/backend.h",
    "main/common_drm.h",
    "main/gbm.c",
    "main/gbm.h",
    "main/gbmint.h",
  ]
}

config("gbm_dri_backend_config") {
  include_dirs = [ "$mesa_build_root/src/gbm/backends/dri" ]
}

source_set("dri_backend") {
  public_configs = [ ":gbm_dri_backend_config" ]

  cflags = [
   "-fPIC",
  ]

  driver_path = rebase_path("$root_out_dir")
  defines = [
    "DEFAULT_DRIVER_DIR=\"$driver_path\"",
  ]

  sources = [
    "backends/dri/gbm_dri.c",
    "backends/dri/gbm_driint.h",
  ]

  deps = [
    ":main",
    "$mesa_build_root/include:GL",
    "$mesa_build_root/include:c_compat",
    "$mesa_build_root/src/loader",
    "$magma_build_root/hacks:libdl_stubs", #todo(MA-7)
    "$magma_build_root/hacks:drm_headers_hacks", #todo(MA-8)
  ]
}