src/MODULE.tools

# NOTE: When editing this file, also update the lockfile.
#   bazel run //src/test/tools/bzlmod:update_default_lock_file
#   bazel mod deps --lockfile_mode=update

module(name = "bazel_tools")

bazel_dep(name = "bazel_skylib", version = "1.9.0")
bazel_dep(name = "buildozer", version = "10.0.1")
bazel_dep(name = "platforms", version = "1.0.0")

# Minimum versions required for compatibility.
bazel_dep(name = "bazel_features", version = "1.43.0", repo_name = None)  # version bump (https://github.com/bazel-contrib/bazel_features/issues/82)
bazel_dep(name = "rules_apple", version = "4.1.0", repo_name = None)  # version bump, older versions contribute lockfile entries
bazel_dep(name = "rules_swift", version = "3.1.2", repo_name = None)  # version bump, older versions don't load CcInfo
bazel_dep(name = "abseil-cpp", version = "20250814.1", repo_name = None)  # version bump, fixes errors with older compilers

xcode_configure = use_extension("@apple_support//xcode:xcode_configure.bzl", "xcode_configure_extension")
use_repo(xcode_configure, "local_config_xcode")

java_toolchains = use_extension("@rules_java//java:extensions.bzl", "toolchains")
use_repo(
    java_toolchains,
    "local_jdk",
    "remote_java_tools",
)

remote_coverage_tools_extension = use_extension("//tools/test:extensions.bzl", "remote_coverage_tools_extension")
use_repo(remote_coverage_tools_extension, "remote_coverage_tools")

# Used by bazel mod tidy (see BazelModTidyFunction).
buildozer_binary = use_extension("@buildozer//:buildozer_binary.bzl", "buildozer_binary")
use_repo(buildozer_binary, "buildozer_binary")

# Needed by module extensions and labels in BUILD and .bzl files in bazel_tools.
# Don't bump these dependencies, they should be removed over time.
# The locations below include subpackages and sources bundled in bazel_tools.

# //tools/proto (defaults of --proto_compiler etc.), //src/main/protobuf.
bazel_dep(name = "protobuf", version = "33.4", repo_name = "com_google_protobuf")

# //tools/{jdk,java,build_rules}, //tools/build_defs/repo, //src/main/native,
# //src/java_tools/{buildjar,import_deps_checker}, and java_toolchains above.
bazel_dep(name = "rules_java", version = "9.7.2")

# //tools/{cpp,jdk,objc,osx,res}, //tools/build_defs/cc, //src/main/{cpp/util,native},
# //src/tools/launcher, //third_party/{def_parser,ijar}.
bazel_dep(name = "rules_cc", version = "0.2.18")

# //tools/python, //tools/build_defs/{hash,pkg}, //third_party/def_parser.
bazel_dep(name = "rules_python", version = "1.7.0")

# //tools/sh, //tools/test, //tools/bash/runfiles.
bazel_dep(name = "rules_shell", version = "0.6.1")

# //tools/objc, //tools/osx
bazel_dep(name = "apple_support", version = "2.6.1")

# //third_party/ijar (zipper built from source when the execution platform differs
# from the host).
bazel_dep(name = "zlib", version = "1.3.1.bcr.5")

winsdk_configure = use_repo_rule("//tools/res:winsdk_configure.bzl", "winsdk_configure")

winsdk_configure(name = "local_config_winsdk")

register_toolchains(
    "//tools/launcher:all",
    "//tools/test:all",
    "@local_config_winsdk//:all",
    "//tools/res:empty_rc_toolchain",
)