Modules/CMakeSYCLInformation.cmake

# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
# file LICENSE.rst or https://cmake.org/licensing for details.


include(CMakeLanguageInformation)

if(UNIX)
  set(CMAKE_SYCL_OUTPUT_EXTENSION .o)
else()
  set(CMAKE_SYCL_OUTPUT_EXTENSION .obj)
endif()

set(_INCLUDED_FILE 0)

if(CMAKE_SYCL_COMPILER_ID)
  include(Compiler/${CMAKE_SYCL_COMPILER_ID}-SYCL OPTIONAL)
endif()

set(CMAKE_BASE_NAME)
get_filename_component(CMAKE_BASE_NAME "${CMAKE_SYCL_COMPILER}" NAME_WE)
if(CMAKE_SYSTEM_PROCESSOR)
  if(CMAKE_SYCL_COMPILER_ID)
    include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_SYCL_COMPILER_ID}-SYCL-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
  endif()
  if(NOT _INCLUDED_FILE)
    include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_BASE_NAME}-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL)
  endif()
endif()

if(CMAKE_SYCL_COMPILER_ID)
  include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_SYCL_COMPILER_ID}-SYCL OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
endif()
if(NOT _INCLUDED_FILE)
  include(Platform/${CMAKE_EFFECTIVE_SYSTEM_NAME}-${CMAKE_BASE_NAME} OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
endif()

if(CMAKE_SYCL_COMPILER_WRAPPER)
  __cmake_include_compiler_wrapper(SYCL)
endif()

if(NOT _INCLUDED_FILE)
  include(Platform/${CMAKE_SYSTEM_NAME} OPTIONAL)
endif()

if(CMAKE_GENERATOR MATCHES "Visual Studio")
  if(NOT CMAKE_SYCL_COMPILER_FRONTEND_VARIANT STREQUAL "MSVC")
    message(FATAL_ERROR "Visual Studio SYCL support requires an MSVC-like compiler frontend.")
  endif()
endif()

if(CMAKE_SYCL_SIZEOF_DATA_PTR)
  foreach(f IN LISTS CMAKE_SYCL_ABI_FILES)
    include(${f})
  endforeach()
  unset(CMAKE_SYCL_ABI_FILES)
endif()

if(_CMAKE_SYCL_REQUIRED_FLAG AND CMAKE_SYCL_COMPILER_FRONTEND_VARIANT STREQUAL "GNU")
  foreach(rule CREATE_PREPROCESSED_SOURCE CREATE_ASSEMBLY_SOURCE)
    if(CMAKE_SYCL_${rule})
      string(REPLACE "<CMAKE_SYCL_COMPILER>" "<CMAKE_SYCL_COMPILER> ${_CMAKE_SYCL_REQUIRED_FLAG}"
        CMAKE_SYCL_${rule} "${CMAKE_SYCL_${rule}}")
    endif()
  endforeach()
endif()

if(CMAKE_USER_MAKE_RULES_OVERRIDE)
  include(${CMAKE_USER_MAKE_RULES_OVERRIDE} RESULT_VARIABLE _override)
  set(CMAKE_USER_MAKE_RULES_OVERRIDE "${_override}")
endif()

if(CMAKE_USER_MAKE_RULES_OVERRIDE_SYCL)
  include(${CMAKE_USER_MAKE_RULES_OVERRIDE_SYCL} RESULT_VARIABLE _override)
  set(CMAKE_USER_MAKE_RULES_OVERRIDE_SYCL "${_override}")
endif()

set(CMAKE_SYCL_FLAGS_INIT "$ENV{SYCLFLAGS} ${CMAKE_SYCL_FLAGS_INIT}")

cmake_initialize_per_config_variable(CMAKE_SYCL_FLAGS "Flags used by the SYCL compiler")

if(CMAKE_SYCL_STANDARD_LIBRARIES_INIT)
  set(CMAKE_SYCL_STANDARD_LIBRARIES "${CMAKE_SYCL_STANDARD_LIBRARIES_INIT}"
    CACHE STRING "Libraries linked by default with all SYCL applications.")
  mark_as_advanced(CMAKE_SYCL_STANDARD_LIBRARIES)
endif()

if(NOT CMAKE_SYCL_COMPILER_LAUNCHER AND DEFINED ENV{CMAKE_SYCL_COMPILER_LAUNCHER})
  set(CMAKE_SYCL_COMPILER_LAUNCHER "$ENV{CMAKE_SYCL_COMPILER_LAUNCHER}"
    CACHE STRING "Compiler launcher for SYCL.")
endif()

if(NOT CMAKE_SYCL_LINKER_LAUNCHER AND DEFINED ENV{CMAKE_SYCL_LINKER_LAUNCHER})
  set(CMAKE_SYCL_LINKER_LAUNCHER "$ENV{CMAKE_SYCL_LINKER_LAUNCHER}"
    CACHE STRING "Linker launcher for SYCL.")
endif()

include(CMakeCommonLanguageInclude)
_cmake_common_language_platform_flags(SYCL)

if(NOT CMAKE_SYCL_CREATE_SHARED_LIBRARY)
  set(CMAKE_SYCL_CREATE_SHARED_LIBRARY
      "<CMAKE_SYCL_COMPILER> ${_CMAKE_SYCL_REQUIRED_FLAG} <CMAKE_SHARED_LIBRARY_SYCL_FLAGS> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> <SONAME_FLAG><TARGET_SONAME> -o <TARGET> <OBJECTS> <LINK_LIBRARIES>")
endif()

if(NOT CMAKE_SYCL_CREATE_SHARED_MODULE)
  set(CMAKE_SYCL_CREATE_SHARED_MODULE ${CMAKE_SYCL_CREATE_SHARED_LIBRARY})
endif()

if(NOT DEFINED CMAKE_SYCL_ARCHIVE_CREATE)
  set(CMAKE_SYCL_ARCHIVE_CREATE "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
endif()
if(NOT DEFINED CMAKE_SYCL_ARCHIVE_APPEND)
  set(CMAKE_SYCL_ARCHIVE_APPEND "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
endif()
if(NOT DEFINED CMAKE_SYCL_ARCHIVE_FINISH)
  set(CMAKE_SYCL_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
endif()

if(NOT CMAKE_SYCL_COMPILE_OBJECT)
  set(CMAKE_SYCL_COMPILE_OBJECT
    "<CMAKE_SYCL_COMPILER> ${_CMAKE_SYCL_REQUIRED_FLAG} <DEFINES> <INCLUDES> <FLAGS> -o <OBJECT> -c <SOURCE>")
endif()

if(NOT CMAKE_SYCL_LINK_EXECUTABLE)
  set(CMAKE_SYCL_LINK_EXECUTABLE
    "<CMAKE_SYCL_COMPILER> ${_CMAKE_SYCL_REQUIRED_FLAG} <FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
endif()

if(CMAKE_SYCL_DEVICE_LINK_OPTIONS)
  set(CMAKE_SYCL_DEVICE_LINK_MODE DRIVER)
  set(CMAKE_SYCL_DEVICE_LINKER_WRAPPER_FLAG ${CMAKE_SYCL_LINKER_WRAPPER_FLAG})
  set(CMAKE_SYCL_DEVICE_LINKER_WRAPPER_FLAG_SEP ${CMAKE_SYCL_LINKER_WRAPPER_FLAG_SEP})
  set(CMAKE_SYCL_RESPONSE_FILE_DEVICE_LINK_FLAG "@")
  string(JOIN " " pic_options ${CMAKE_SYCL_COMPILE_OPTIONS_PIC})
  string(JOIN " " device_options ${CMAKE_SYCL_DEVICE_LINK_OPTIONS})
  if(NOT CMAKE_SYCL_DEVICE_LINK_LIBRARY)
    set(CMAKE_SYCL_DEVICE_LINK_LIBRARY
      "<CMAKE_SYCL_COMPILER> <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> ${pic_options} ${device_options} -o <TARGET> <OBJECTS> <LINK_LIBRARIES>")
  endif()
  if(NOT CMAKE_SYCL_DEVICE_LINK_EXECUTABLE)
    set(CMAKE_SYCL_DEVICE_LINK_EXECUTABLE "${CMAKE_SYCL_DEVICE_LINK_LIBRARY}")
  endif()
  unset(device_options)
  unset(pic_options)
endif()

mark_as_advanced(CMAKE_VERBOSE_MAKEFILE)

set(CMAKE_SYCL_USE_LINKER_INFORMATION TRUE)

set(CMAKE_SYCL_INFORMATION_LOADED 1)