gdb/testsuite/gdb.testsuite/gdb-test.exp

# Copyright 2022-2025 Free Software Foundation, Inc.
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# The purpose of this test-case is to check various
# gdb_test / gdb_test_multiple properties.

clean_restart

# Check that a command with trailing newline triggers an error.

with_test_prefix "cmd with trailing newline" {
    set results [catch {
	gdb_test "pwd\n" ".*" "pwd"
    } output]

    gdb_assert { $results == 1 }
    set expected_error_msg "Invalid trailing newline in \"pwd\n\" command"
    gdb_assert { [string equal $output $expected_error_msg] }
}

with_test_prefix "cmd with trailing control code" {
    foreach_with_prefix control_code {^C ^D} {
	switch $control_code {
	    ^C {
		set cmd "\003"
	    }
	    ^D {
		set cmd "\004"
	    }
	}
	set results [catch {
	    gdb_test $cmd ".*" "control code"
	} output]

	gdb_assert { $results == 1 }
	set expected_error_msg "Invalid trailing control code in \"$cmd\" command"
	gdb_assert { [string equal $output $expected_error_msg] }
    }
}

# Change the prompt.
set prompt "(GDB) "
set prompt_re "\\(GDB\\) $"
gdb_test -prompt $prompt_re "set prompt $prompt"

gdb_test_multiple "print 1" "" -prompt $prompt_re {
    -re -wrap " = 1" {
	pass $gdb_test_name
    }
}