gdb/testsuite/gdb.base/attach-deleted-exec.exp

# Copyright (C) 2024-2025 Free Software Foundation, Inc.
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program.  If not, see <http://www.gnu.org/licenses/>.

# Attach to a process, the executable for which has been deleted.  On
# GNU/Linux GDB will spot the missing executable and fallback to use
# /proc/PID/exe instead.

require can_spawn_for_attach
require {istarget *-linux*}

standard_testfile

if { [build_executable "failed to prepare" $testfile $srcfile] } {
    return -1
}

set test_spawn_id [spawn_wait_for_attach $binfile]
set testpid [spawn_id_get_pid $test_spawn_id]

# Move the executable rather than deleting it.  This just to aid with
# debugging if someone needs to reproduce this test.
set binfile_moved ${binfile}_moved

# Don't move BINFILE as the kernel will just assign a new name to the
# same inode; and the /proc/PID/exe link will continue to point to the
# renamed inode.
remote_exec host "cp $binfile $binfile_moved"
remote_exec host "rm $binfile"

# Don't pass the executable when GDB starts.  Instead rely on GDB
# finding the executable from the PID we attach too.
clean_restart

# Attach.  GDB should spot that the executable is gone and fallback to
# use /proc/PID/exe.
set test "attach to process with deleted executable"
set re \
    [multi_line \
	 "Attaching to process $decimal" \
	 "Reading symbols from (\[^\r\n\]+)[string_to_regexp ...]" \
	 ".*"]
set filename ""
gdb_test_multiple "attach $testpid" $test {
    -re -wrap $re {
	set filename $expect_out(1,string)
	pass $gdb_test_name
    }
}

set test "filename /proc/PID/exe"
set re_nfs \[^\r\n\]+[string_to_regexp /.nfs]\[^\r\n\]+
if { [regexp $re_nfs $filename] } {
    unsupported $test
} else {
    gdb_assert { [string equal $filename /proc/${testpid}/exe] } $test
}

# Restart GDB.
clean_restart

# Setup an empty sysroot.  GDB will fail to find the executable within
# the sysroot.  Additionally, the presence of a sysroot should prevent
# GDB from trying to load the executable from /proc/PID/exe.
set sysroot [standard_output_file "sysroot"]
gdb_test_no_output "set sysroot $sysroot" \
    "setup sysroot"

# Attach to the inferior.  GDB should complain about failing to find
# the executable.  It is the name of the executable that GDB doesn't
# find that we're interesting in here.  For native targets GDB should
# be looking for BINFILE, not /proc/PID/exe.
#
# For extended-remote targets things are unfortunately harder.  Native
# GDB looks for BINFILE because it understands that GDB will be
# looking in the sysroot.  But remote GDB doesn't know if GDB is using
# a sysroot or not.  As such, gdbserver will return /proc/PID/exe if
# it knows that the file has been deleted locally.  This isn't great
# if GDB then plans to look in a sysroot, but equally, if the remote
# file has been deleted, then the name GDB will return, will have had
# " (deleted" appended, so we're unlikely to get a hit in the sysroot
# either way.
if { [target_info gdb_protocol] == "extended-remote" } {
    set filename_re "/proc/$testpid/exe"
} else {
    set filename_re "\[^\r\n\]+/${testfile} \\(deleted\\)"
}

verbose -log "APB: warning: No executable has been specified, and target executable $filename_re could not be found\\.  Try using the \"file\" command\\."

gdb_test "attach $testpid" \
    [multi_line \
	 "Attaching to process $decimal" \
	 "warning: No executable has been specified, and target executable $filename_re could not be found\\.  Try using the \"file\" command\\." \
	 ".*"] \
    "attach to inferior"

# Check GDB hasn't managed to load an executable.
gdb_test "info inferior" \
    "\\*\[^)\]+\\)\\s*" \
    "confirm no executable is loaded."

# Cleanup.
kill_wait_spawned_process $test_spawn_id