public/lib/fsl/BUILD.gn

# Copyright 2016 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//packages/package.gni")

group("fsl") {
  public_deps = [
    ":fsl_lib",
    "//zircon/system/ulib/fbl",
    "//zircon/system/ulib/fs",
    "//zircon/system/ulib/zx",
  ]
}

shared_library("fsl_lib") {
  output_name = "fsl"

  public_deps = [
    "//garnet/public/lib/fsl/handles",
    "//garnet/public/lib/fsl/io",
    "//garnet/public/lib/fsl/socket",
    "//garnet/public/lib/fsl/tasks",
    "//garnet/public/lib/fsl/threading",
    "//garnet/public/lib/fsl/vmo",
    "//garnet/public/lib/fsl/waiter",
  ]
}

executable("fsl_unittests") {
  testonly = true

  sources = [
    "handles/object_info_unittest.cc",
    "io/redirection_unittest.cc",
    "socket/blocking_drain_unittest.cc",
    "socket/files_unittest.cc",
    "socket/socket_drainer_unittest.cc",
    "socket/strings_unittest.cc",
    "tasks/fd_waiter_unittest.cc",
    "tasks/message_loop_unittest.cc",
    "threading/create_thread_unittest.cc",
    "threading/thread_unittest.cc",
    "vmo/file_unittest.cc",
    "vmo/shared_vmo_unittest.cc",
    "vmo/strings_unittest.cc",
    "vmo/vector_unittest.cc",
  ]

  deps = [
    ":fsl",
    "//garnet/public/lib/fxl/test:gtest_main",
    "//third_party/gtest",
  ]
}

package("package") {
  testonly = true

  package_name = "fsl"

  deps = [
    ":fsl",
    ":fsl_unittests",
  ]

  libraries = [ {
        name = "libfsl.so"
      } ]

  tests = [ {
        name = "fsl_unittests"
      } ]
}