lib/magma/BUILD.gn

# Copyright 2016 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/package.gni")
import("//garnet/lib/magma/gnbuild/magma.gni")

# TODO(MA-416): should libmagma be a source set?
package("libmagma") {
  deprecated_system_image = true
  deps = [
    "//garnet/lib/magma/src/libmagma",
  ]
  libraries = [
    {
      name = "libmagma.so"
    },
  ]
}

package("magma-tools") {
  deprecated_system_image = true

  deps = [
    ":tools",
  ]

  binaries = [
    {
      name = "magma_info"
    },
  ]
}

package("vkcube") {
  deprecated_system_image = true

  if (have_libvulkan || use_vulkan_loader_for_tests) {
    deps = [
      "//garnet/lib/magma/tests/vkcube",
    ]

    binaries = [
      {
        name = "vkcube"
      },
    ]
  }
}

# This config allows inclusion of headers via relative paths from src
config("magma_src_include_config") {
  include_dirs = [ "src" ]
}

# This config allows inclusion of headers via relative paths from tests
config("magma_tests_include_config") {
  include_dirs = [ "tests" ]
}

group("tools") {
  public_deps = [
    "src/tools",
  ]
}