lib/vulkan/src/swapchain/BUILD.gn

# Copyright 2017 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

loader_build_root = "//third_party/vulkan_loader_and_validation_layers"

source_set("surface_header") {
  sources = [
    "image_pipe_surface.h",
  ]
  public_deps = [
    "$loader_build_root:vulkan",
    "//garnet/public/fidl/fuchsia.images",
  ]
}

loadable_module("swapchain") {
  output_name = "libVkLayer_image_pipe_swapchain"
  sources = [
    "image_pipe_surface_async.cc",
    "image_pipe_surface_async.h",
    "image_pipe_swapchain_layer.cc",
  ]
  include_dirs = [
    "$loader_build_root/include",
    "$loader_build_root/loader",
    "$loader_build_root/layers",
    "$loader_build_root/icd/common/",
  ]
  deps = [
    ":surface_header",
    "$loader_build_root:extra_vulkan_headers",
    "$loader_build_root/layers:micro_layer_common",
    "//zircon/public/lib/async-loop-cpp",
  ]
  ldflags = [ "-static-libstdc++" ]
}

loadable_module("fb") {
  output_name = "libVkLayer_image_pipe_swapchain_fb"
  defines = [ "USE_IMAGEPIPE_SURFACE_FB" ]
  sources = [
    "image_pipe_surface_fb.cc",
    "image_pipe_surface_fb.h",
    "image_pipe_swapchain_layer.cc",
  ]
  include_dirs = [
    "$loader_build_root/include",
    "$loader_build_root/loader",
    "$loader_build_root/layers",
    "$loader_build_root/icd/common/",
  ]
  deps = [
    ":surface_header",
    "$loader_build_root:extra_vulkan_headers",
    "$loader_build_root/layers:micro_layer_common",
    "//zircon/public/lib/async-loop-cpp",
    "//zircon/public/lib/framebuffer",
  ]
  ldflags = [ "-static-libstdc++" ]
}