src/ui/examples/shadertoy/service/BUILD.gn

# Copyright 2017 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

executable("bin") {
  output_name = "shadertoy_service"

  sources = [
    "app.cc",
    "app.h",
    "compiler.cc",
    "compiler.h",
    "imagepipe_shadertoy.cc",
    "imagepipe_shadertoy.h",
    "main.cc",
    "pipeline.cc",
    "pipeline.h",
    "renderer.cc",
    "renderer.h",
    "shadertoy_impl.cc",
    "shadertoy_impl.h",
    "shadertoy_state.cc",
    "shadertoy_state.h",
    "view_shadertoy.cc",
    "view_shadertoy.h",
  ]

  deps = [
    "services",
    "//sdk/fidl/fuchsia.ui.gfx",
    "//sdk/lib/fidl/cpp",
    "//sdk/lib/sys/cpp",
    "//sdk/lib/ui/scenic/cpp",
    "//src/lib/fsl",
    "//src/lib/fxl",
    "//src/lib/vulkan",
    "//src/ui/examples/escher/common",

    # Shadertoy service should always use glslang.
    "//sdk/lib/fit",
    "//src/ui/lib/escher:escher_with_glslang",
    "//third_party/glm",
    "//third_party/shaderc:libshaderc",
    "//zircon/system/ulib/async-loop:async-loop-cpp",
    "//zircon/system/ulib/async-loop:async-loop-default",
    "//zircon/system/ulib/trace-provider",
  ]

  include_dirs = [
    "//lib",
    "//src/ui/lib/escher",
  ]

  # TODO(fxb/58162): delete the below and fix compiler warnings
  configs += [ "//build/config:Wno-conversion" ]
}

group("service") {
  deps = [ ":shadertoy_service" ]
}

fuchsia_package_with_single_component("shadertoy_service") {
  manifest = "meta/shadertoy_service.cmx"
  deps = [
    ":bin",
    "//src/lib/vulkan:vulkan_validation_layers",
  ]
}