src/settings/factory_reset/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")

group("factory_reset") {
  testonly = true
  deps = [
    ":settings_factory_reset",
    ":tests",
  ]
}

rustc_library("settings_factory_reset") {
  name = "settings_factory_reset"
  with_unit_tests = true
  edition = "2024"

  visibility = [
    ":*",
    "//src/settings/service:*",
  ]

  deps = [
    "//sdk/fidl/fuchsia.recovery.policy:fuchsia.recovery.policy_rust",
    "//sdk/fidl/fuchsia.settings:fuchsia.settings_rust",
    "//src/lib/async-utils",
    "//src/lib/fuchsia-async",
    "//src/settings/common:settings_common",
    "//src/settings/storage:settings_storage",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:serde",
    "//third_party/rust_crates:thiserror",
  ]

  sources = [
    "src/factory_reset_controller.rs",
    "src/factory_reset_fidl_handler.rs",
    "src/lib.rs",
    "src/types.rs",
  ]

  configs += [ "//build/config/rust/lints:deny_unused_results" ]
  configs += [ "//build/config/rust/lints:clippy_warn_all" ]
}

fuchsia_unittest_package("settings_factory_reset_tests") {
  component_name = "settings_factory_reset_test"
  manifest = "meta/settings_factory_reset_tests.cml"
  deps = [ ":settings_factory_reset_test" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [ ":settings_factory_reset_tests" ]
}