src/power/cpu-manager/integration/tests/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

resource("domain-controller-integration-test-resources") {
  sources = [
    "config_files/domain_controller_test/cpu_manager_node_config.json5",
    "config_files/domain_controller_test/power_manager_node_config.json5",
    "config_files/domain_controller_test/thermal_config.json5",
  ]
  outputs = [ "domain_controller_test/{{source_file_part}}" ]
}

rustc_test("domain-controller-integration-test-bin") {
  name = "domain_controller_integration_test"
  testonly = true
  edition = "2024"
  source_root = "src/domain_controller_test.rs"
  deps = [
    "//sdk/fidl/fuchsia.power.cpu:fuchsia.power.cpu_rust",
    "//src/lib/fuchsia",
    "//src/power/power-manager/integration/lib",
  ]

  sources = [ "src/domain_controller_test.rs" ]
}

fuchsia_unittest_package("domain-controller-integration-test") {
  manifest = "meta/domain-controller-integration-test.cml"
  deps = [
    ":domain-controller-integration-test-bin",
    ":domain-controller-integration-test-resources",
    "//src/power/power-manager/testing/fake_driver:component",
    "//src/power/power-manager/testing/fake_driver:fake-cpu-ctrl-component",
    "//src/power/power-manager/testing/fake_root",
  ]

  test_specs = {
    # CpuManager emits "Expected positive total_time_delta" error message
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

group("tests") {
  testonly = true
  deps = [ ":domain-controller-integration-test" ]
}