src/connectivity/ethernet/drivers/usb-cdc-function/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/components.gni")
import("//build/drivers.gni")
import("//build/test.gni")

driver_bind_rules("usb_cdc_bind") {
  rules = "meta/usb_cdc.bind"
  bind_output = "usb-cdc-function.bindbc"
  tests = "meta/bind-tests.json"
  deps = [
    "//src/devices/bind/fuchsia.usb",
    "//src/devices/bind/fuchsia.usb.comm",
  ]
}

source_set("usb-cdc-function-common") {
  sources = [
    "usb-cdc-function.cc",
    "usb-cdc-function.h",
  ]
  public_deps = [
    "//sdk/fidl/fuchsia.hardware.network.driver:fuchsia.hardware.network.driver_cpp",
    "//sdk/fidl/fuchsia.hardware.usb.endpoint:fuchsia.hardware.usb.endpoint_cpp",
    "//sdk/fidl/fuchsia.hardware.usb.function:fuchsia.hardware.usb.function_cpp",
    "//sdk/lib/driver/compat/cpp",
    "//src/devices/usb/lib/usb",
    "//src/devices/usb/lib/usb-endpoint:usb-endpoint-client-dfv2-compat-logging",
    "//src/lib/vmo_store",
  ]
  deps = [
    "//sdk/fidl/fuchsia.boot.metadata:fuchsia.boot.metadata_cpp",
    "//sdk/fidl/fuchsia.hardware.network:fuchsia.hardware.network_cpp",
    "//sdk/lib/driver/component/cpp",
    "//sdk/lib/driver/metadata/cpp",
    "//src/devices/usb/lib/usb:cdc",
    "//src/devices/usb/lib/usb:peripheral",
    "//zircon/system/ulib/sync",
    "//zircon/system/ulib/sync:sync-cpp",
    "//zircon/system/ulib/trace",
  ]
}

fuchsia_cc_driver("usb-cdc-function-driver") {
  output_name = "usb-cdc-function"
  deps = [
    ":usb-cdc-function-common",
    ":usb_cdc_bind",
    "//sdk/lib/driver/runtime:driver_runtime_cpp",
  ]
}

fuchsia_driver_component("usb-cdc-function") {
  # LINT.IfChange(cdc_driver_component_name_tefmo)
  component_name = "usb-cdc-function"
  deps = [ ":usb-cdc-function-driver" ]
  info = "meta/usb-cdc-function-info.json"
  manifest = "meta/usb-cdc-function.cml"

  # LINT.ThenChange(//tools/testing/tefmocheck/cdc_ethernet_state_check.go:cdc_driver_component_name_tefmo)
}

fuchsia_driver_package("package") {
  package_name = "usb-cdc-function"
  driver_components = [ ":usb-cdc-function" ]
}

test("usb-cdc-function-test") {
  sources = [ "usb-cdc-function-test.cc" ]
  deps = [
    ":usb-cdc-function-common",
    "//sdk/fidl/fuchsia.boot.metadata:fuchsia.boot.metadata_cpp",
    "//sdk/fidl/fuchsia.hardware.network.driver:fuchsia.hardware.network.driver_cpp_testing",
    "//sdk/fidl/fuchsia.hardware.usb.function:fuchsia.hardware.usb.function_cpp",
    "//sdk/lib/async-default",
    "//sdk/lib/async-loop:async-loop-cpp",
    "//sdk/lib/async-loop:async-loop-default",
    "//sdk/lib/driver/metadata/cpp",
    "//sdk/lib/driver/testing/cpp",
    "//src/devices/usb/lib/usb-endpoint:fake-usb-endpoint-server-zxtest",
    "//zircon/system/ulib/zxtest",
  ]
}

fuchsia_unittest_package("usb-cdc-function-unittest") {
  package_name = "usb-cdc-function-test"
  deps = [ ":usb-cdc-function-test" ]
}

group("tests") {
  testonly = true
  deps = [
    ":usb-cdc-function-unittest",
    ":usb_cdc_bind_test",
  ]
}