pw_chrono/BUILD.gn

# Copyright 2020 The Pigweed Authors
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may not
# use this file except in compliance with the License. You may obtain a copy of
# the License at
#
#     https://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations under
# the License.

import("//build_overrides/pigweed.gni")

import("$dir_pw_build/facade.gni")
import("$dir_pw_chrono/backend.gni")
import("$dir_pw_docgen/docs.gni")
import("$dir_pw_protobuf_compiler/proto.gni")
import("$dir_pw_unit_test/test.gni")

config("public_include_path") {
  include_dirs = [ "public" ]
  visibility = [ ":*" ]
}

pw_source_set("epoch") {
  public = [ "public/pw_chrono/epoch.h" ]
  public_configs = [ ":public_include_path" ]
}

pw_source_set("virtual_clock") {
  public = [ "public/pw_chrono/virtual_clock.h" ]
  public_configs = [ ":public_include_path" ]
}

pw_facade("system_clock") {
  backend = pw_chrono_SYSTEM_CLOCK_BACKEND
  public_configs = [ ":public_include_path" ]
  public = [
    "public/pw_chrono/internal/system_clock_macros.h",
    "public/pw_chrono/system_clock.h",
  ]
  public_deps = [
    ":epoch",
    ":virtual_clock",
    "$dir_pw_preprocessor",
  ]
  sources = [ "system_clock.cc" ]
}

pw_facade("system_timer") {
  backend = pw_chrono_SYSTEM_TIMER_BACKEND
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_chrono/system_timer.h" ]
  public_deps = [
    ":system_clock",
    dir_pw_function,
  ]
}

# Dependency injectable implementation of pw::chrono::SystemClock::Interface.
pw_source_set("simulated_system_clock") {
  public_configs = [ ":public_include_path" ]
  public = [ "public/pw_chrono/simulated_system_clock.h" ]
  public_deps = [
    ":system_clock",
    "$dir_pw_sync:interrupt_spin_lock",
  ]
}

pw_test_group("tests") {
  tests = [
    ":simulated_system_clock_test",
    ":system_clock_facade_test",
    ":system_timer_facade_test",
  ]
}

pw_test("simulated_system_clock_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [ "simulated_system_clock_test.cc" ]
  deps = [ ":simulated_system_clock" ]
}

pw_test("system_clock_facade_test") {
  enable_if = pw_chrono_SYSTEM_CLOCK_BACKEND != ""
  sources = [
    "system_clock_facade_test.cc",
    "system_clock_facade_test_c.c",
  ]
  deps = [
    ":system_clock",
    dir_pw_preprocessor,
    pw_chrono_SYSTEM_CLOCK_BACKEND,
  ]
}

pw_test("system_timer_facade_test") {
  enable_if = pw_chrono_SYSTEM_TIMER_BACKEND != ""
  sources = [ "system_timer_facade_test.cc" ]
  deps = [
    ":system_timer",
    "$dir_pw_sync:thread_notification",
    pw_chrono_SYSTEM_TIMER_BACKEND,
  ]
}

# The ":time" target wraps the time() and gettimeofday(), which are
# commonly used by TLS libraries for expiration check.
config("time_wrap") {
  # Link options that wrap C time calls.
  ldflags = [
    "-Wl,--wrap=time",
    "-Wl,--wrap=gettimeofday",
  ]
  visibility = [ ":*" ]
}

# The build time is obtained with a python script and put in a generated header
# file. The header file is included in build_time.cc
pw_python_action("generate_build_time_header") {
  header_output = "$target_gen_dir/pw_chrono/build_time.h"
  script = "generate_build_time_header.py"
  outputs = [ header_output ]
  args = [ rebase_path(header_output) ]
}

# The target provides a backend to :time that returns build time.
pw_source_set("wrap_time_build_time") {
  all_dependent_configs = [ ":time_wrap" ]
  include_dirs =
      [ get_label_info(":generate_build_time_header", "target_gen_dir") ]
  sources = [ "wrap_time_build_time.cc" ]
  deps = [ ":generate_build_time_header" ]
}

pw_source_set("wrap_time_system_clock") {
  all_dependent_configs = [ ":time_wrap" ]
  sources = [ "wrap_time_system_clock.cc" ]
  deps = [ ":system_clock" ]
}

pw_proto_library("protos") {
  sources = [ "chrono.proto" ]
  prefix = "pw_chrono_protos"
}

pw_doc_group("docs") {
  sources = [
    "backends.rst",
    "docs.rst",
  ]
}