src/intel/ds/BUILD.gn

# Copyright 2022 The Fuchsia Authors, LLC
#
# Permission is hereby granted, free of charge, to any person obtaining a
# copy of this software and associated documentation files (the "Software"),
# to deal in the Software without restriction, including without limitation
# the rights to use, copy, modify, merge, publish, distribute, sublicense,
# and/or sell copies of the Software, and to permit persons to whom the
# Software is furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice (including the next
# paragraph) shall be included in all copies or substantial portions of the
# Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
# THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
# FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
# IN THE SOFTWARE.

import("../../../mesa.gni")

config("ds_config") {
  include_dirs = [
    "$target_gen_dir",
    "$mesa_build_root/src/mesa"
  ]
}

mesa_source_set("ds") {
  public_configs = [ ":ds_config" ]

  public_deps = [
    ":gen_tracepoints",
    "$mesa_build_root/src/compiler/nir",
  ]

  sources = [
    "intel_driver_ds.cc",
    "$target_gen_dir/intel_tracepoints.c",
  ]

  include_dirs = [ "." ]

  deps = [
    "$mesa_build_root/src/intel/common",
  ]
}

mesa_python_action("gen_tracepoints") {
  script = "intel_tracepoints.py"

  output_h = "$target_gen_dir/intel_tracepoints.h"
  output_perfetto_h = "$target_gen_dir/intel_tracepoints_perfetto.h"
  output_c = "$target_gen_dir/intel_tracepoints.c"

  outputs = [
    output_h,
    output_perfetto_h,
    output_c,
  ]

  inputs = [ "//third_party/mesa/src/util/perf/u_trace.py" ]

  args = [
    "-p",
    rebase_path("//third_party/mesa/src/util/perf", root_build_dir),
    "--utrace-hdr",
    rebase_path(output_h, root_build_dir),
    "--perfetto-hdr",
    rebase_path(output_perfetto_h, root_build_dir),
    "--utrace-src",
    rebase_path(output_c, root_build_dir),
  ]
}