# Copyright 2019 The Fuchsia Authors. All rights reserved.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions are
# met:
#
#    * Redistributions of source code must retain the above copyright
# notice, this list of conditions and the following disclaimer.
#    * Redistributions in binary form must reproduce the above
# copyright notice, this list of conditions and the following disclaimer
# in the documentation and/or other materials provided with the
# distribution.
#    * Neither the name of Google Inc. nor the names of its
# contributors may be used to endorse or promote products derived from
# this software without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
# "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
# LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
# A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
# OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
# OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

group("libffi") {
  public_deps = [ ":ffi_static" ]
}

config("ffi_headers") {
  visibility = [ ":*" ]
  include_dirs = [ "./include" ]
  if (current_cpu == "x64") {
    include_dirs += [
      "./include/x86",
      "${target_gen_dir}/x86",
    ]
  }
  if (current_cpu == "arm64") {
    include_dirs += [
      "./include/aarch64",
      "${target_gen_dir}/aarch64",
    ]
  }
}

config("ffi_static_config") {
  cflags = [
    # Suppress warnings in upstream code that are triggered by Fuchsia compilation flags.
    "-Wno-conversion",
    "-Wno-null-pointer-arithmetic",
    "-Wno-sign-compare",

    # For asm keyword in src/aarch64/ffi.c
    "-std=gnu11",
  ]
}

source_set("ffi_static") {
  visibility = [ ":*" ]

  public_configs = [ ":ffi_headers" ]

  include_dirs = [
    "./include",
    "./src",
  ]

  sources = [
    "src/closures.c",
    "src/prep_cif.c",
    "src/types.c",
  ]

  if (current_cpu == "x64") {
    include_dirs += [ "./src/x86" ]
    deps = [ ":target_x86" ]
    sources += [
      "src/x86/ffi64.c",
      "src/x86/ffiw64.c",
      "src/x86/unix64.S",
      "src/x86/win64.S",
    ]
  }

  if (current_cpu == "arm64") {
    include_dirs += [ "./src/aarch64" ]
    defines = [ "_GNU_SOURCE" ]
    deps = [ ":target_aarch64" ]
    sources += [
      "src/aarch64/ffi.c",
      "src/aarch64/sysv.S",
    ]
  }

  configs += [ ":ffi_static_config" ]
}

copy("target_x86") {
  sources = [ "src/x86/ffitarget.h" ]
  outputs = [ "${target_gen_dir}/x86/ffitarget.h" ]
}

copy("target_aarch64") {
  sources = [ "src/aarch64/ffitarget.h" ]
  outputs = [ "${target_gen_dir}/aarch64/ffitarget.h" ]
}