| #*************************************************************************** | |
| # _ _ ____ _ | |
| # Project ___| | | | _ \| | | |
| # / __| | | | |_) | | | |
| # | (__| |_| | _ <| |___ | |
| # \___|\___/|_| \_\_____| | |
| # | |
| # Copyright (C) Daniel Stenberg, <daniel@haxx.se>, et al. | |
| # | |
| # This software is licensed as described in the file COPYING, which | |
| # you should have received as part of this distribution. The terms | |
| # are also available at https://curl.se/docs/copyright.html. | |
| # | |
| # You may opt to use, copy, modify, merge, publish, distribute and/or sell | |
| # copies of the Software, and permit persons to whom the Software is | |
| # furnished to do so, under the terms of the COPYING file. | |
| # | |
| # This software is distributed on an "AS IS" basis, WITHOUT WARRANTY OF ANY | |
| # KIND, either express or implied. | |
| # | |
| # SPDX-License-Identifier: curl | |
| # | |
| ########################################################################### | |
| # Find the ldap library | |
| # | |
| # Input variables: | |
| # | |
| # - `LDAP_INCLUDE_DIR`: Absolute path to ldap include directory. | |
| # - `LDAP_LIBRARY`: Absolute path to `ldap` library. | |
| # - `LDAP_LBER_LIBRARY`: Absolute path to `lber` library. | |
| # | |
| # Defines: | |
| # | |
| # - `LDAP_FOUND`: System has ldap. | |
| # - `LDAP_VERSION`: Version of ldap. | |
| # - `CURL::ldap`: ldap library target. | |
| set(_ldap_pc_requires "ldap" "lber") | |
| if(CURL_USE_PKGCONFIG AND | |
| NOT DEFINED LDAP_INCLUDE_DIR AND | |
| NOT DEFINED LDAP_LIBRARY AND | |
| NOT DEFINED LDAP_LBER_LIBRARY) | |
| find_package(PkgConfig QUIET) | |
| pkg_check_modules(_ldap ${_ldap_pc_requires}) | |
| endif() | |
| if(_ldap_FOUND) | |
| set(LDAP_FOUND TRUE) | |
| set(LDAP_VERSION ${_ldap_ldap_VERSION}) | |
| message(STATUS "Found LDAP (via pkg-config): ${_ldap_INCLUDE_DIRS} (found version \"${LDAP_VERSION}\")") | |
| else() | |
| set(_ldap_pc_requires "") # Depend on pkg-config only when found via pkg-config | |
| # On Apple the SDK LDAP gets picked up from | |
| # 'MacOSX.sdk/System/Library/Frameworks/LDAP.framework/Headers', which contains | |
| # ldap.h and lber.h both being stubs to include <ldap.h> and <lber.h>. | |
| # This causes an infinite inclusion loop in compile. Also do this for libraries | |
| # to avoid picking up the 'ldap.framework' with a full path. | |
| set(_save_cmake_system_framework_path ${CMAKE_SYSTEM_FRAMEWORK_PATH}) | |
| set(CMAKE_SYSTEM_FRAMEWORK_PATH "") | |
| find_path(LDAP_INCLUDE_DIR NAMES "ldap.h") | |
| find_library(LDAP_LIBRARY NAMES "ldap") | |
| find_library(LDAP_LBER_LIBRARY NAMES "lber") | |
| set(CMAKE_SYSTEM_FRAMEWORK_PATH ${_save_cmake_system_framework_path}) | |
| unset(LDAP_VERSION CACHE) | |
| if(LDAP_INCLUDE_DIR AND EXISTS "${LDAP_INCLUDE_DIR}/ldap_features.h") | |
| set(_version_regex1 "#[\t ]*define[\t ]+LDAP_VENDOR_VERSION_MAJOR[\t ]+([0-9]+).*") | |
| set(_version_regex2 "#[\t ]*define[\t ]+LDAP_VENDOR_VERSION_MINOR[\t ]+([0-9]+).*") | |
| set(_version_regex3 "#[\t ]*define[\t ]+LDAP_VENDOR_VERSION_PATCH[\t ]+([0-9]+).*") | |
| file(STRINGS "${LDAP_INCLUDE_DIR}/ldap_features.h" _version_str1 REGEX "${_version_regex1}") | |
| file(STRINGS "${LDAP_INCLUDE_DIR}/ldap_features.h" _version_str2 REGEX "${_version_regex2}") | |
| file(STRINGS "${LDAP_INCLUDE_DIR}/ldap_features.h" _version_str3 REGEX "${_version_regex3}") | |
| string(REGEX REPLACE "${_version_regex1}" "\\1" _version_str1 "${_version_str1}") | |
| string(REGEX REPLACE "${_version_regex2}" "\\1" _version_str2 "${_version_str2}") | |
| string(REGEX REPLACE "${_version_regex3}" "\\1" _version_str3 "${_version_str3}") | |
| set(LDAP_VERSION "${_version_str1}.${_version_str2}.${_version_str3}") | |
| unset(_version_regex1) | |
| unset(_version_regex2) | |
| unset(_version_regex3) | |
| unset(_version_str1) | |
| unset(_version_str2) | |
| unset(_version_str3) | |
| endif() | |
| include(FindPackageHandleStandardArgs) | |
| find_package_handle_standard_args(LDAP | |
| REQUIRED_VARS | |
| LDAP_INCLUDE_DIR | |
| LDAP_LIBRARY | |
| LDAP_LBER_LIBRARY | |
| VERSION_VAR | |
| LDAP_VERSION | |
| ) | |
| if(LDAP_FOUND) | |
| set(_ldap_INCLUDE_DIRS ${LDAP_INCLUDE_DIR}) | |
| set(_ldap_LIBRARIES ${LDAP_LIBRARY} ${LDAP_LBER_LIBRARY}) | |
| endif() | |
| mark_as_advanced(LDAP_INCLUDE_DIR LDAP_LIBRARY LDAP_LBER_LIBRARY) | |
| endif() | |
| if(LDAP_FOUND) | |
| if(NOT TARGET CURL::ldap) | |
| add_library(CURL::ldap INTERFACE IMPORTED) | |
| set_target_properties(CURL::ldap PROPERTIES | |
| INTERFACE_LIBCURL_PC_MODULES "${_ldap_pc_requires}" | |
| INTERFACE_COMPILE_OPTIONS "${_ldap_CFLAGS}" | |
| INTERFACE_INCLUDE_DIRECTORIES "${_ldap_INCLUDE_DIRS}" | |
| INTERFACE_LINK_DIRECTORIES "${_ldap_LIBRARY_DIRS}" | |
| INTERFACE_LINK_LIBRARIES "${_ldap_LIBRARIES}") | |
| endif() | |
| endif() |