bin/media/codecs/sw/ffmpeg/BUILD.gn

# Copyright 2018 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/test.gni")
import("//build/test/test_package.gni")

executable("codec_runner_sw_ffmpeg") {
  visibility = [
    "//garnet/bin/media/codec_factory",
    "//garnet/bin/media:codec_runner_sw_ffmpeg",
    "//garnet/bin/media:codec_runner_sw_ffmpeg.manifest",
    "//garnet/bin/media/*",  # TODO(CF-235): Dep shouldn' be needed
  ]

  sources = [
    "avcodec_context.cc",
    "avcodec_context.h",
    "buffer_pool.cc",
    "buffer_pool.h",
    "codec_adapter_ffmpeg_decoder.cc",
    "codec_adapter_ffmpeg_decoder.h",
    "codec_runner_app.cc",
    "codec_runner_app.h",
    "local_single_codec_factory.cc",
    "local_single_codec_factory.h",
    "main.cc",
    "mpsc_queue.h",
  ]

  deps = [
    "//garnet/lib/media/codec_impl",
    "//garnet/lib/media/ffmpeg",
    "//garnet/public/fidl/fuchsia.mediacodec",
    "//garnet/public/lib/component/cpp",
    "//zircon/public/lib/async-loop-cpp",
  ]
}

source_set("mpsc_queue") {
  visibility = [ "//garnet/bin/media/codecs/sw/ffmpeg/*" ]

  public = [
    "mpsc_queue.h",
  ]

  public_deps = [
    "//zircon/public/lib/fit",
  ]
}

executable("codec_runner_sw_ffmpeg_test_bin") {
  output_name = "codec_runner_sw_ffmpeg_tests"

  testonly = true

  sources = [
    "test/codec_runner_sw_ffmpeg_tests.cc",
  ]

  deps = [
    ":mpsc_queue",
    "//garnet/public/lib/fsl",
    "//third_party/googletest:gtest_main",
    "//zircon/public/lib/async-loop-cpp",
  ]
}

test_package("codec_runner_sw_ffmpeg_tests") {
  deps = [
    ":codec_runner_sw_ffmpeg_test_bin",
  ]

  tests = [
    {
      name = "codec_runner_sw_ffmpeg_tests"
    },
  ]
}