# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/fuchsia/rules.gni")
import("//build/test.gni")
import("//build/test/test_package.gni")
import("//build/unification/images/migrated_manifest.gni")

driver_module("lite-on") {
  defines = [ "_ALL_SOURCE" ]
  configs += [ "//build/config/fuchsia:enable_zircon_asserts" ]
  configs -= [ "//build/config/fuchsia:no_cpp_standard_library" ]
  configs += [ "//build/config/fuchsia:static_cpp_standard_library" ]
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
  }
  sources = [ "ltr-578als.cc" ]
  deps = [
    "//sdk/banjo/ddk.protocol.hidbus",
    "//src/devices/i2c/lib/device-protocol-i2c-channel",
    "//src/devices/lib/driver",
    "//zircon/public/lib/ddk",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/device-protocol-i2c",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fit",
    "//zircon/public/lib/mmio",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/zx",
    "//zircon/system/banjo/ddk.protocol.i2c",
    "//zircon/system/ulib/hid",
    "//zircon/system/ulib/simplehid",
  ]
}

test("ltr-578als-test") {
  defines = [ "_ALL_SOURCE" ]
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
  }
  if (is_fuchsia) {
    fdio_config = [ "//build/config/fuchsia:fdio_config" ]
    if (configs + fdio_config - fdio_config != configs) {
      configs -= fdio_config
    }
  }
  output_name = "ltr-578als-test"
  sources = [
    "ltr-578als-test.cc",
    "ltr-578als.cc",
  ]
  deps = [
    "//src/devices/i2c/lib/device-protocol-i2c-channel",
    "//src/devices/i2c/testing/mock-i2c",
    "//src/devices/testing/fake_ddk",
    "//src/ui/input/testing/mock-hidbus-ifc",
    "//zircon/public/lib/ddktl",
    "//zircon/public/lib/device-protocol-i2c",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/fit",
    "//zircon/public/lib/mmio",
    "//zircon/public/lib/sync",
    "//zircon/public/lib/unittest",
    "//zircon/public/lib/zx",
    "//zircon/public/lib/zxtest",
    "//zircon/system/banjo/ddk.protocol.i2c",
    "//zircon/system/ulib/hid",
    "//zircon/system/ulib/simplehid",
  ]
}

migrated_manifest("lite-on-manifest") {
  deps = [ ":lite-on" ]
}

unittest_package("ltr-578als-test-package") {
  package_name = "ltr-578als-test"
  deps = [ ":ltr-578als-test" ]

  tests = [
    {
      name = "ltr-578als-test"
      environments = basic_envs
    },
  ]
}

group("tests") {
  testonly = true
  deps = [ ":ltr-578als-test-package" ]
}