src/devices/board/drivers/c18/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/bind/bind.gni")
import("//build/config/fuchsia/rules.gni")

bind_rules("c18_bind") {
  rules = "c18.bind"
  output = "c18_bind.h"
  tests = "bind_tests.json"
  deps = [
    "//src/devices/bind/fuchsia.google.platform",
    "//src/devices/bind/fuchsia.platform",
  ]
}

group("tests") {
  testonly = true
  deps = [ ":c18_bind_test" ]
}

driver_module("c18") {
  configs += [
    "//build/config:all_source",
    "//build/config/fuchsia:enable_zircon_asserts",
  ]
  if (is_fuchsia) {
    configs += [ "//build/unification/config:zircon-migrated" ]
  }
  sources = [
    "c18-gpio.cc",
    "c18-msdc0.cc",
    "c18-soc.cc",
    "c18-spi.cc",
    "c18.cc",
  ]
  deps = [
    ":c18_bind",
    "//sdk/banjo/fuchsia.hardware.gpioimpl",
    "//sdk/banjo/fuchsia.hardware.platform.bus",
    "//src/devices/lib/driver",
    "//src/devices/lib/mmio",
    "//src/devices/lib/mt8167",
    "//src/devices/lib/mt8183",
    "//src/lib/ddk",
    "//src/lib/ddktl",
    "//zircon/public/lib/zx",
  ]

  # TODO(fxbug.dev/47406): restore some form of data dependency on c18
  # boot shim.
}