zircon/system/ulib/hid-parser/test/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

##########################################
# Though under //zircon, this build file #
# is meant to be used in the Fuchsia GN  #
# build.                                 #
# See fxbug.dev/36139.                   #
##########################################

assert(!defined(zx) || zx != "/",
       "This file can only be used in the Fuchsia GN build.")

import("//build/fuzzing/fuzzer.gni")
import("//build/test.gni")
import("//build/test/test_package.gni")
import("//build/testing/bootfs_test.gni")

group("tests") {
  testonly = true
  deps = [
    ":hid-fuzzers",
    ":hid-parser-package",
  ]
}

test("hid-parser") {
  output_name = "hid-parser-test"
  configs += [ "//build/unification/config:zircon-migrated" ]
  sources = [
    "hid-descriptor-test.cc",
    "hid-helper-test.cc",
    "hid-parser-test.cc",
    "hid-report-data.cc",
    "hid-units-test.cc",
    "hid-utest-data.cc",
  ]
  deps = [
    "//sdk/lib/fdio",
    "//zircon/public/lib/fbl",
    "//zircon/public/lib/zxtest",
    "//zircon/system/ulib/hid",
    "//zircon/system/ulib/hid-parser",
  ]
}

unittest_package("hid-parser-package") {
  package_name = "hid-parser-test"
  deps = [ ":hid-parser" ]
  tests = [
    {
      name = "hid-parser-test"
      environments = basic_envs
    },
  ]
}

fuzzer("hid-parser-fuzzer") {
  sources = [ "hid-parser-fuzztest.cc" ]
  deps = [
    "//zircon/public/lib/fbl",
    "//zircon/system/ulib/hid-parser",
  ]
}

fuzzers_package("hid-fuzzers") {
  cpp_fuzzers = [ ":hid-parser-fuzzer" ]
}