src/connectivity/management/reachability/core/BUILD.gn

# Copyright 2019 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/rust/rustc_library.gni")
import("//src/sys/build/fuchsia_unittest_package.gni")

rustc_library("lib") {
  name = "reachability_core"
  version = "0.1.0"
  edition = "2018"
  with_unit_tests = true
  non_rust_deps = [ ":ext_ping" ]

  deps = [
    "//sdk/fidl/fuchsia.net:fuchsia.net-rustc",
    "//sdk/fidl/fuchsia.net.dhcp:fuchsia.net.dhcp-rustc",
    "//sdk/fidl/fuchsia.net.filter:fuchsia.net.filter-rustc",
    "//sdk/fidl/fuchsia.net.stack:fuchsia.net.stack-rustc",
    "//sdk/fidl/fuchsia.netstack:fuchsia.netstack-rustc",
    "//sdk/fidl/fuchsia.router.config:fuchsia.router.config-rustc",
    "//src/connectivity/lib/net-types",
    "//src/connectivity/management/network-manager/core:lib",
    "//src/lib/diagnostics/inspect/contrib/rust",
    "//src/lib/diagnostics/inspect/rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/network/fidl_fuchsia_net_ext",
    "//src/lib/network/fidl_fuchsia_net_stack_ext",
    "//src/lib/syslog/rust:syslog",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:libc",
    "//third_party/rust_crates:log",
    "//third_party/rust_crates:thiserror",
  ]

  test_deps = [
    "//src/connectivity/lib/net-declare",
    "//src/lib/fidl/rust/fidl",
  ]

  sources = [
    "src/inspect.rs",
    "src/lib.rs",
    "src/ping.rs",
  ]
}

static_library("ext_ping") {
  sources = [ "src/ping.cc" ]
  deps = [ "//zircon/public/lib/zx" ]
}

fuchsia_unittest_package("reachability-core-lib-test") {
  deps = [ ":lib_test" ]
  executable_path = "bin/reachability_core_lib_test"
}

group("tests") {
  testonly = true
  deps = [ ":reachability-core-lib-test" ]
}