src/storage/conformance/BUILD.gn

# Copyright 2020 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")
import("//build/rust/rustc_library.gni")
import("//build/rust/rustc_test.gni")

# Full list of io1 conformance tests should be included here. Add deps to the
# test packages for additional filesystem conformance tests and test harnesses.
# TODO(https://fxbug.dev/293947862): Remove the `io1` suffix from the harnesses and update
# nomenclature once io1 and io2 have been merged.
group("tests") {
  testonly = true
  deps = [
    ":io_conformance_util_tests",
    "//src/storage/conformance/conformance_harness/cppvfs:cppvfs-io1-conformance-test",
    "//src/storage/conformance/conformance_harness/fxfs:fxfs-conformance-test",
    "//src/storage/conformance/conformance_harness/memfs:memfs-conformance-test",
    "//src/storage/conformance/conformance_harness/minfs:minfs-io1-conformance-test",
    "//src/storage/conformance/conformance_harness/rustvfs:rustvfs-io1-conformance-test",
    "//src/storage/conformance/conformance_harness/sdkcpp:sdkcpp-conformance-test",
  ]
}

rustc_library("io_conformance_util") {
  name = "io_conformance_util"
  with_unit_tests = true
  edition = "2021"
  testonly = true
  deps = [
    "//sdk/fidl/fuchsia.component:fuchsia.component_rust",
    "//sdk/fidl/fuchsia.component.decl:fuchsia.component.decl_rust",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//sdk/fidl/fuchsia.io.test:fuchsia.io.test_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-component",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/storage/lib/vfs/rust:vfs",
    "//third_party/rust_crates:async-trait",
    "//third_party/rust_crates:futures",
  ]

  sources = [
    "src/flags.rs",
    "src/lib.rs",
    "src/test_harness.rs",
  ]
}

fuchsia_unittest_package("io_conformance_util_tests") {
  deps = [ ":io_conformance_util_test" ]
}

rustc_test("io1_conformance_test") {
  name = "io1_conformance_test"
  edition = "2021"
  source_root = "tests/tests.rs"
  deps = [
    ":io_conformance_util",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-fs",
    "//src/lib/zircon/rust:fuchsia-zircon",
    "//src/storage/lib/vfs/rust:vfs",
    "//third_party/rust_crates:assert_matches",
    "//third_party/rust_crates:futures",
  ]

  sources = [
    "tests/attributes.rs",
    "tests/clone_reopen.rs",
    "tests/describe.rs",
    "tests/directory.rs",
    "tests/directory/create.rs",
    "tests/directory/enumerate.rs",
    "tests/directory/get_token.rs",
    "tests/directory/link.rs",
    "tests/directory/open.rs",
    "tests/directory/rename.rs",
    "tests/directory/unlink.rs",
    "tests/directory/watch.rs",
    "tests/file.rs",
    "tests/file/get_backing_memory.rs",
    "tests/file/link_into.rs",
    "tests/file/read.rs",
    "tests/file/resize.rs",
    "tests/file/write.rs",
    "tests/get_connection_info.rs",
    "tests/node.rs",
    "tests/remote.rs",
    "tests/tests.rs",
  ]
}