| # Copyright 2018 The Fuchsia Authors. All rights reserved. |
| # Use of this source code is governed by a BSD-style license that can be |
| # found in the LICENSE file. |
| |
| import("//build/rust/rustc_artifact.gni") |
| import("//build/rust/rustc_test.gni") |
| |
| # Defines a Rust static library |
| # |
| # Parameters |
| # |
| # output_name (optional) |
| # name (optional, deprecated) |
| # Name of the crate as defined in its manifest file. If not specified, it is |
| # assumed to be the same as the target name. |
| # |
| # version |
| # Semver version of the crate as seen on crates.io. |
| # |
| # edition |
| # Edition of the Rust language to be used. See |
| # https://doc.rust-lang.org/edition-guide/editions/index.html for more info on rust editions. |
| # |
| # configs (optional) |
| # A list of config labels applying to this target. |
| # |
| # test_configs (optional) |
| # A list of config labels applying to the test target, in addition to those in `configs`. |
| # |
| # enforce_source_listing (optional) |
| # When true, enforces that any source files used by the Rust compiler are |
| # listed in `sources`. Defaults to true. |
| # |
| # sources (optional) |
| # List of source files which this crate is allowed to compile. Only |
| # allowed when `enforce_source_listing = true`. |
| # The Rust compiler discovers source files by following `mod` declarations |
| # starting at the `source_root`. The discovered source files must match this |
| # list. |
| # |
| # inputs (optional) |
| # List of additional non-source files read by the compiler. These are typically |
| # configuration or test-data files included in the build with the `include_str!` |
| # macro. Only allowed when `enforce_source_listing = true`. |
| # |
| # deps (optional) |
| # List of rust_library GN targets on which this crate depends. |
| # Third party crates can be included through paths like |
| # "//third_party/rust_crates:<cratename>", |
| # |
| # test_deps (optional) |
| # List of rust_library GN targets on which this crate's tests depend in addition to those in |
| # `deps`. |
| # |
| # non_rust_deps (optional) |
| # List of non-rust_library GN targets on which this crate depends. |
| # Obsolete. Please use deps instead. |
| # |
| # data_deps (optional) |
| # List of GN targets that are only needed at runtime. |
| # |
| # with_unit_tests (optional) |
| # Builds unit tests associated with the binary. This will create a |
| # `<name>-bin-unit-test` test file in the output directory. |
| # |
| # source_root (optional) |
| # Location of the crate root (e.g. `src/main.rs` or `src/lib.rs`). |
| # This defaults to `./src/main.rs` for binaries and `./src/lib.rs` for libraries, |
| # and should only be changed when absolutely necessary |
| # (such as in the case of generated code). |
| # |
| # features (optional) |
| # A list of conditional compilation flags to enable. This can be used to set features for crates |
| # built in-tree which are also published to crates.io. This would be passed to rustc as |
| # '--cfg feature="XXX"' |
| # |
| # rustenv (optional) |
| # A list of environment variables that will be set when running the rust |
| # compiler. These can be accessed at compile time with |
| # [`std::env!`](https://doc.rust-lang.org/stable/std/macro.env.html) |
| # |
| # output_dir (optional) |
| # Directory that the resulting library should be placed in. |
| # See: `gn help output_dir` |
| # |
| # disable_rbe (optional) |
| # Set to true to force this target to build locally, overriding the global |
| # `rust_rbe_enable`. |
| # |
| # disable_clippy (optional) |
| # Don't run clippy on this target. |
| # |
| # disable_rustdoc (optional) |
| # Don't add this target to https://fuchsia.dev/go/rustdoc |
| # |
| # original_target_name (optional) |
| # The name of the target as it appears in the BUILD file. Enables tooling |
| # to find the template invocation in a BUILD file where this target was defined. |
| # |
| # Example of usage: |
| # |
| # rustc_staticlib("foo") { |
| # deps = [ |
| # "//garnet/public/rust/bar", |
| # "//third_party/rust_crates:argh", |
| # "//third_party/rust_crates:serde", |
| # "//third_party/rust_crates:slab", |
| # ] |
| # with_unit_tests = true |
| # sources = [ "src/lib.rs" ] |
| # } |
| template("rustc_staticlib") { |
| if (defined(invoker.original_target_name)) { |
| _original_target_name = invoker.original_target_name |
| } else { |
| _original_target_name = target_name |
| } |
| not_needed(invoker, [ "version" ]) |
| assert(!(defined(invoker.output_name) && defined(invoker.name)), |
| "Only one of output_name and name may be specified.") |
| |
| # if "with_unit_tests" is set to true, generate an additional rust test target |
| # TODO(https://fxbug.dev/42152447): accept a string. |
| if (defined(invoker.with_unit_tests) && invoker.with_unit_tests) { |
| rustc_test_internal("${target_name}_test") { |
| not_needed(invoker, [ "public" ]) |
| original_target_name = _original_target_name |
| deps = [] |
| forward_variables_from(invoker, |
| "*", |
| [ |
| "name", |
| "output_name", |
| "test_configs", |
| "test_deps", |
| ]) |
| output_name = invoker.target_name + "_staticlib_test" |
| if (defined(invoker.output_name)) { |
| output_name = invoker.output_name + "_staticlib_test" |
| } else if (defined(invoker.name)) { |
| output_name = invoker.name + "_staticlib_test" |
| } |
| if (defined(invoker.test_configs)) { |
| configs += invoker.test_configs |
| } |
| if (defined(invoker.test_deps)) { |
| deps += invoker.test_deps |
| } |
| } |
| } |
| |
| group_target = target_name |
| |
| rustc_target = "_${target_name}_rustc_static" |
| if (defined(invoker.output_name)) { |
| rustc_target = "_${invoker.output_name}_rustc_static" |
| } else if (defined(invoker.name)) { |
| rustc_target = "_${invoker.name}_rustc_static" |
| } |
| rustc_target = string_replace(rustc_target, "-", "_") |
| |
| if (!defined(invoker.source_root)) { |
| source_root = "src/lib.rs" |
| } else { |
| source_root = invoker.source_root |
| } |
| |
| rustc_artifact(rustc_target) { |
| target_type = "static_library" |
| crate_root = source_root |
| clippy_crate_type = "staticlib" |
| crate_name = rustc_target |
| pass_through = { |
| forward_variables_from(invoker, [ "output_dir" ]) |
| output_name = rustc_target |
| } |
| original_target_name = _original_target_name |
| |
| deps = [] |
| if (defined(invoker.deps)) { |
| deps += invoker.deps |
| } |
| |
| # TODO(https://fxbug.dev/42120123) remove "non_rust_deps" |
| if (defined(invoker.non_rust_deps)) { |
| deps += invoker.non_rust_deps |
| } |
| |
| forward_variables_from(invoker, |
| [ |
| "disable_clippy", |
| "edition", |
| "enforce_source_listing", |
| "features", |
| "inputs", |
| "rustenv", |
| "sources", |
| "testonly", |
| "visibility", |
| ]) |
| |
| configs = [] |
| configs = invoker.configs |
| metadata = { |
| if (defined(invoker.disable_rustdoc)) { |
| disable_rustdoc = [ invoker.disable_rustdoc ] |
| } |
| } |
| } |
| |
| public_hdrs = [] |
| if (defined(invoker.public)) { |
| public_hdrs += invoker.public |
| } |
| |
| header_target = "_${rustc_target}_staticlib_headers" |
| |
| source_set(header_target) { |
| public = public_hdrs |
| visibility = [ ":${group_target}" ] |
| deps = [] |
| if (defined(invoker.non_rust_deps)) { |
| # TODO(https://fxbug.dev/42120123): This allows propagating non rust dependencies through a |
| # single level of indirection, but does not handle propagating |
| # dependencies through an intermediate Rust target. |
| deps += invoker.non_rust_deps |
| } |
| } |
| |
| group(group_target) { |
| forward_variables_from(invoker, |
| [ |
| "data_deps", |
| "testonly", |
| "visibility", |
| ]) |
| public_deps = [ |
| ":$header_target", |
| ":$rustc_target", |
| ] |
| } |
| } |
