src/ui/tools/print-input-report/BUILD.gn

# Copyright 2026 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/assembly/bootfs_files_for_assembly.gni")
import("//build/components.gni")
import("//build/rust/rustc_binary.gni")

rustc_binary("bin") {
  output_name = "print-input-report"
  edition = "2024"
  with_unit_tests = true

  sources = [
    "src/commands.rs",
    "src/commands/get_descriptor.rs",
    "src/commands/list.rs",
    "src/commands/read.rs",
    "src/common.rs",
    "src/descriptor_types.rs",
    "src/indented_serializer.rs",
    "src/input_report_types.rs",
    "src/main.rs",
    "src/testing.rs",
    "src/testing/fake_input_device.rs",
  ]
  deps = [
    "//sdk/fidl/fuchsia.input.report:fuchsia.input.report_rust_next",
    "//sdk/fidl/fuchsia.io:fuchsia.io_rust",
    "//sdk/rust/zx",
    "//src/lib/fdio/rust:fdio",
    "//src/lib/fidl/rust/fidl",
    "//src/lib/fidl/rust_next/fidl_next",
    "//src/lib/fuchsia",
    "//src/lib/fuchsia-fs",
    "//third_party/rust_crates:anyhow",
    "//third_party/rust_crates:argh",
    "//third_party/rust_crates:csv",
    "//third_party/rust_crates:futures",
    "//third_party/rust_crates:prettytable-rs",
    "//third_party/rust_crates:serde",
    "//third_party/rust_crates:serde_json",
  ]
  test_deps = [
    "//sdk/fidl/fuchsia.input:fuchsia.input_rust_next",
    "//src/lib/fuchsia-async",
    "//src/lib/fuchsia-sync",
    "//src/storage/lib/vfs/rust:vfs",
    "//third_party/rust_crates:googletest",
    "//third_party/rust_crates:log",
  ]
}

fuchsia_unittest_package("print-input-report-tests") {
  deps = [ ":bin_test" ]
  test_specs = {
    log_settings = {
      max_severity = "ERROR"
    }
  }
}

bootfs_files_for_assembly("bootfs") {
  deps = [ ":bin" ]
}

group("tests") {
  testonly = true
  deps = [ ":print-input-report-tests" ]
}