src/graphics/drivers/msd-vsi-vip/tests/BUILD.gn

# Copyright 2025 The Fuchsia Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/components.gni")

group("tests") {
  testonly = true
  deps = [
    ":magma-conformance-tests-vsi",
    ":msd-vsi-vip-integration-tests",
  ]
}

fuchsia_unittest_package("msd-vsi-vip-integration-tests") {
  manifest = "meta/msd_vsi_vip_integration_tests.cml"
  deps = [
    "integration:msd_vsi_vip_integration_tests",
    "//src/graphics/drivers/msd-vsi-vip:msd_vsi_test",
  ]
  test_specs = {
    environments = [
      sherlock_env,
      vim3_env,
    ]
    log_settings = {
      max_severity = "ERROR"
    }
  }
  test_type = "device"
}

fuchsia_component("vendor-helper-vsi-component") {
  testonly = true
  component_name = "vendor-helper"
  manifest = "meta/vendor-helper.cml"
  deps = [ "integration:magma-conformance-vendor-helper-vsi" ]
}

fuchsia_test_component("magma-conformance-tests-vsi-component") {
  component_name = "magma-conformance-tests"
  manifest = "meta/magma-conformance-tests-vsi.cml"
  test_type = "system"
}

fuchsia_test_package("magma-conformance-tests-vsi") {
  test_components = [ ":magma-conformance-tests-vsi-component" ]
  subpackages =
      [ "//src/graphics/magma/tests/integration:magma-conformance-tests-child" ]
  deps = [ ":vendor-helper-vsi-component" ]
  test_specs = {
    environments = [
      sherlock_env,
      vim3_env,
    ]
    log_settings = {
      max_severity = "ERROR"
    }
  }
}